double ? = Double;

string ? = String;

int32 = Int32;

int53 = Int53;

int64 = Int64;

bytes = Bytes;

boolFalse = Bool;

boolTrue = Bool;

vector {t:Type} # [ t ] = Vector t;

//@description An object of this type can be returned on every function call, in case of an error

//@code Error code; subject to future changes. If the error code is 406, the error message must not be processed in any way and must not be displayed to the user

//@message Error message; subject to future changes

error code:int32 message:string = Error;

//@description An object of this type is returned on a successful function call for certain functions

ok = Ok;

//@class AuthenticationCodeType @description Provides information about the method by which an authentication code is delivered to the user

//@description A digit-only authentication code is delivered via a private Telegram message, which can be viewed from another active session

//@length Length of the code

authenticationCodeTypeTelegramMessage length:int32 = AuthenticationCodeType;

//@description A digit-only authentication code is delivered via an SMS message to the specified phone number; non-official applications may not receive this type of code

//@length Length of the code

authenticationCodeTypeSms length:int32 = AuthenticationCodeType;

//@description An authentication code is a word delivered via an SMS message to the specified phone number; non-official applications may not receive this type of code

//@first_letter The first letters of the word if known

authenticationCodeTypeSmsWord first_letter:string = AuthenticationCodeType;

//@description An authentication code is a phrase from multiple words delivered via an SMS message to the specified phone number; non-official applications may not receive this type of code

//@first_word The first word of the phrase if known

authenticationCodeTypeSmsPhrase first_word:string = AuthenticationCodeType;

//@description A digit-only authentication code is delivered via a phone call to the specified phone number

//@length Length of the code

authenticationCodeTypeCall length:int32 = AuthenticationCodeType;

//@description An authentication code is delivered by an immediately canceled call to the specified phone number. The phone number that calls is the code that must be entered automatically

//@pattern Pattern of the phone number from which the call will be made

authenticationCodeTypeFlashCall pattern:string = AuthenticationCodeType;

//@description An authentication code is delivered by an immediately canceled call to the specified phone number. The last digits of the phone number that calls are the code that must be entered manually by the user

//@phone_number_prefix Prefix of the phone number from which the call will be made

//@length Number of digits in the code, excluding the prefix

authenticationCodeTypeMissedCall phone_number_prefix:string length:int32 = AuthenticationCodeType;

//@description A digit-only authentication code is delivered to https://fragment.com. The user must be logged in there via a wallet owning the phone number's NFT

//@url URL to open to receive the code

//@length Length of the code

authenticationCodeTypeFragment url:string length:int32 = AuthenticationCodeType;

//@description A digit-only authentication code is delivered via Firebase Authentication to the official Android application

//@device_verification_parameters Parameters to be used for device verification

//@length Length of the code

authenticationCodeTypeFirebaseAndroid device_verification_parameters:FirebaseDeviceVerificationParameters length:int32 = AuthenticationCodeType;

//@description A digit-only authentication code is delivered via Firebase Authentication to the official iOS application

//@receipt Receipt of successful application token validation to compare with receipt from push notification

//@push_timeout Time after the next authentication method is expected to be used if verification push notification isn't received, in seconds

//@length Length of the code

authenticationCodeTypeFirebaseIos receipt:string push_timeout:int32 length:int32 = AuthenticationCodeType;

//@description Information about the authentication code that was sent

//@phone_number A phone number that is being authenticated

//@type The way the code was sent to the user

//@next_type The way the next code will be sent to the user; may be null

//@timeout Timeout before the code can be re-sent, in seconds

authenticationCodeInfo phone_number:string type:AuthenticationCodeType next_type:AuthenticationCodeType timeout:int32 = AuthenticationCodeInfo;

//@description Information about the email address authentication code that was sent

//@email_address_pattern Pattern of the email address to which an authentication code was sent

//@length Length of the code; 0 if unknown

emailAddressAuthenticationCodeInfo email_address_pattern:string length:int32 = EmailAddressAuthenticationCodeInfo;

//@class EmailAddressAuthentication @description Contains authentication data for an email address

//@description An authentication code delivered to a user's email address @code The code

emailAddressAuthenticationCode code:string = EmailAddressAuthentication;

//@description An authentication token received through Apple ID @token The token

emailAddressAuthenticationAppleId token:string = EmailAddressAuthentication;

//@description An authentication token received through Google ID @token The token

emailAddressAuthenticationGoogleId token:string = EmailAddressAuthentication;

//@class EmailAddressResetState @description Describes reset state of an email address

//@description Email address can be reset after the given period. Call resetAuthenticationEmailAddress to reset it and allow the user to authorize with a code sent to the user's phone number

//@wait_period Time required to wait before the email address can be reset; 0 if the user is subscribed to Telegram Premium

emailAddressResetStateAvailable wait_period:int32 = EmailAddressResetState;

//@description Email address reset has already been requested. Call resetAuthenticationEmailAddress to check whether immediate reset is possible

//@reset_in Left time before the email address will be reset, in seconds. updateAuthorizationState is not sent when this field changes

emailAddressResetStatePending reset_in:int32 = EmailAddressResetState;

//@description Represents a part of the text that needs to be formatted in some unusual way @offset Offset of the entity, in UTF-16 code units @length Length of the entity, in UTF-16 code units @type Type of the entity

textEntity offset:int32 length:int32 type:TextEntityType = TextEntity;

//@description Contains a list of text entities @entities List of text entities

textEntities entities:vector<textEntity> = TextEntities;

//@description A text with some entities @text The text @entities Entities contained in the text. Entities can be nested, but must not mutually intersect with each other.

//-Pre, Code and PreCode entities can't contain other entities. BlockQuote entities can't contain other BlockQuote entities. Bold, Italic, Underline, Strikethrough, and Spoiler entities can contain and can be part of any other entities. All other entities can't contain each other

formattedText text:string entities:vector<textEntity> = FormattedText;

//@description Contains Telegram terms of service @text Text of the terms of service @min_user_age The minimum age of a user to be able to accept the terms; 0 if age isn't restricted @show_popup True, if a blocking popup with terms of service must be shown to the user

termsOfService text:formattedText min_user_age:int32 show_popup:Bool = TermsOfService;

//@class AuthorizationState @description Represents the current authorization state of the TDLib client

//@description Initialization parameters are needed. Call setTdlibParameters to provide them

authorizationStateWaitTdlibParameters = AuthorizationState;

//@description TDLib needs the user's phone number to authorize. Call setAuthenticationPhoneNumber to provide the phone number, or use requestQrCodeAuthentication or checkAuthenticationBotToken for other authentication options

authorizationStateWaitPhoneNumber = AuthorizationState;

//@description TDLib needs the user's email address to authorize. Call setAuthenticationEmailAddress to provide the email address, or directly call checkAuthenticationEmailCode with Apple ID/Google ID token if allowed

//@allow_apple_id True, if authorization through Apple ID is allowed

//@allow_google_id True, if authorization through Google ID is allowed

authorizationStateWaitEmailAddress allow_apple_id:Bool allow_google_id:Bool = AuthorizationState;

//@description TDLib needs the user's authentication code sent to an email address to authorize. Call checkAuthenticationEmailCode to provide the code

//@allow_apple_id True, if authorization through Apple ID is allowed

//@allow_google_id True, if authorization through Google ID is allowed

//@code_info Information about the sent authentication code

//@email_address_reset_state Reset state of the email address; may be null if the email address can't be reset

authorizationStateWaitEmailCode allow_apple_id:Bool allow_google_id:Bool code_info:emailAddressAuthenticationCodeInfo email_address_reset_state:EmailAddressResetState = AuthorizationState;

//@description TDLib needs the user's authentication code to authorize. Call checkAuthenticationCode to check the code @code_info Information about the authorization code that was sent

authorizationStateWaitCode code_info:authenticationCodeInfo = AuthorizationState;

//@description The user needs to confirm authorization on another logged in device by scanning a QR code with the provided link @link A tg:// URL for the QR code. The link will be updated frequently

authorizationStateWaitOtherDeviceConfirmation link:string = AuthorizationState;

//@description The user is unregistered and need to accept terms of service and enter their first name and last name to finish registration. Call registerUser to accept the terms of service and provide the data @terms_of_service Telegram terms of service

authorizationStateWaitRegistration terms_of_service:termsOfService = AuthorizationState;

//@description The user has been authorized, but needs to enter a 2-step verification password to start using the application.

//-Call checkAuthenticationPassword to provide the password, or requestAuthenticationPasswordRecovery to recover the password, or deleteAccount to delete the account after a week

//@password_hint Hint for the password; may be empty

//@has_recovery_email_address True, if a recovery email address has been set up

//@has_passport_data True, if some Telegram Passport elements were saved

//@recovery_email_address_pattern Pattern of the email address to which the recovery email was sent; empty until a recovery email has been sent

authorizationStateWaitPassword password_hint:string has_recovery_email_address:Bool has_passport_data:Bool recovery_email_address_pattern:string = AuthorizationState;

//@description The user has been successfully authorized. TDLib is now ready to answer general requests

authorizationStateReady = AuthorizationState;

//@description The user is currently logging out

authorizationStateLoggingOut = AuthorizationState;

//@description TDLib is closing, all subsequent queries will be answered with the error 500. Note that closing TDLib can take a while. All resources will be freed only after authorizationStateClosed has been received

authorizationStateClosing = AuthorizationState;

//@description TDLib client is in its final state. All databases are closed and all resources are released. No other updates will be received after this. All queries will be responded to

//-with error code 500. To continue working, one must create a new instance of the TDLib client

authorizationStateClosed = AuthorizationState;

//@class FirebaseDeviceVerificationParameters @description Describes parameters to be used for device verification

//@description Device verification must be performed with the SafetyNet Attestation API @nonce Nonce to pass to the SafetyNet Attestation API

firebaseDeviceVerificationParametersSafetyNet nonce:bytes = FirebaseDeviceVerificationParameters;

//@description Device verification must be performed with the classic Play Integrity verification (https://developer.android.com/google/play/integrity/classic)

//@nonce Base64url-encoded nonce to pass to the Play Integrity API

//@cloud_project_number Cloud project number to pass to the Play Integrity API

firebaseDeviceVerificationParametersPlayIntegrity nonce:string cloud_project_number:int64 = FirebaseDeviceVerificationParameters;

//@description Represents the current state of 2-step verification

//@has_password True, if a 2-step verification password is set

//@password_hint Hint for the password; may be empty

//@has_recovery_email_address True, if a recovery email is set

//@has_passport_data True, if some Telegram Passport elements were saved

//@recovery_email_address_code_info Information about the recovery email address to which the confirmation email was sent; may be null

//@login_email_address_pattern Pattern of the email address set up for logging in

//@pending_reset_date If not 0, point in time (Unix timestamp) after which the 2-step verification password can be reset immediately using resetPassword

passwordState has_password:Bool password_hint:string has_recovery_email_address:Bool has_passport_data:Bool recovery_email_address_code_info:emailAddressAuthenticationCodeInfo login_email_address_pattern:string pending_reset_date:int32 = PasswordState;

//@description Contains information about the current recovery email address @recovery_email_address Recovery email address

recoveryEmailAddress recovery_email_address:string = RecoveryEmailAddress;

//@description Returns information about the availability of a temporary password, which can be used for payments @has_password True, if a temporary password is available @valid_for Time left before the temporary password expires, in seconds

temporaryPasswordState has_password:Bool valid_for:int32 = TemporaryPasswordState;

//@description Represents a local file

//@path Local path to the locally available file part; may be empty

//@can_be_downloaded True, if it is possible to download or generate the file

//@can_be_deleted True, if the file can be deleted

//@is_downloading_active True, if the file is currently being downloaded (or a local copy is being generated by some other means)

//@is_downloading_completed True, if the local copy is fully available

//@download_offset Download will be started from this offset. downloaded_prefix_size is calculated from this offset

//@downloaded_prefix_size If is_downloading_completed is false, then only some prefix of the file starting from download_offset is ready to be read. downloaded_prefix_size is the size of that prefix in bytes

//@downloaded_size Total downloaded file size, in bytes. Can be used only for calculating download progress. The actual file size may be bigger, and some parts of it may contain garbage

localFile path:string can_be_downloaded:Bool can_be_deleted:Bool is_downloading_active:Bool is_downloading_completed:Bool download_offset:int53 downloaded_prefix_size:int53 downloaded_size:int53 = LocalFile;

//@description Represents a remote file

//@id Remote file identifier; may be empty. Can be used by the current user across application restarts or even from other devices. Uniquely identifies a file, but a file can have a lot of different valid identifiers.

//-If the identifier starts with "http://" or "https://", it represents the HTTP URL of the file. TDLib is currently unable to download files if only their URL is known.

//-If downloadFile/addFileToDownloads is called on such a file or if it is sent to a secret chat, TDLib starts a file generation process by sending updateFileGenerationStart to the application with the HTTP URL in the original_path and "#url#" as the conversion string.

//-Application must generate the file by downloading it to the specified location

//@unique_id Unique file identifier; may be empty if unknown. The unique file identifier which is the same for the same file even for different users and is persistent over time

//@is_uploading_active True, if the file is currently being uploaded (or a remote copy is being generated by some other means)

//@is_uploading_completed True, if a remote copy is fully available

//@uploaded_size Size of the remote available part of the file, in bytes; 0 if unknown

remoteFile id:string unique_id:string is_uploading_active:Bool is_uploading_completed:Bool uploaded_size:int53 = RemoteFile;

//@description Represents a file

//@id Unique file identifier

//@size File size, in bytes; 0 if unknown

//@expected_size Approximate file size in bytes in case the exact file size is unknown. Can be used to show download/upload progress

//@local Information about the local copy of the file

//@remote Information about the remote copy of the file

file id:int32 size:int53 expected_size:int53 local:localFile remote:remoteFile = File;

//@class InputFile @description Points to a file

//@description A file defined by its unique identifier @id Unique file identifier

inputFileId id:int32 = InputFile;

//@description A file defined by its remote identifier. The remote identifier is guaranteed to be usable only if the corresponding file is still accessible to the user and known to TDLib.

//-For example, if the file is from a message, then the message must be not deleted and accessible to the user. If the file database is disabled, then the corresponding object with the file must be preloaded by the application

//@id Remote file identifier

inputFileRemote id:string = InputFile;

//@description A file defined by a local path @path Local path to the file

inputFileLocal path:string = InputFile;

//@description A file generated by the application. The application must handle updates updateFileGenerationStart and updateFileGenerationStop to generate the file when asked by TDLib

//@original_path Local path to a file from which the file is generated. The path doesn't have to be a valid path and is used by TDLib only to detect name and MIME type of the generated file

//@conversion String specifying the conversion applied to the original file; must be persistent across application restarts. Conversions beginning with '#' are reserved for internal TDLib usage

//@expected_size Expected size of the generated file, in bytes; pass 0 if unknown

inputFileGenerated original_path:string conversion:string expected_size:int53 = InputFile;

//@description Describes an image in JPEG format

//@type Image type (see https://core.telegram.org/constructor/photoSize)

//@photo Information about the image file

//@width Image width

//@height Image height

//@progressive_sizes Sizes of progressive JPEG file prefixes, which can be used to preliminarily show the image; in bytes

photoSize type:string photo:file width:int32 height:int32 progressive_sizes:vector<int32> = PhotoSize;

//@description Thumbnail image of a very poor quality and low resolution @width Thumbnail width, usually doesn't exceed 40 @height Thumbnail height, usually doesn't exceed 40 @data The thumbnail in JPEG format

minithumbnail width:int32 height:int32 data:bytes = Minithumbnail;

//@class ThumbnailFormat @description Describes format of a thumbnail

//@description The thumbnail is in JPEG format

thumbnailFormatJpeg = ThumbnailFormat;

//@description The thumbnail is in static GIF format. It will be used only for some bot inline query results

thumbnailFormatGif = ThumbnailFormat;

//@description The thumbnail is in MPEG4 format. It will be used only for some animations and videos

thumbnailFormatMpeg4 = ThumbnailFormat;

//@description The thumbnail is in PNG format. It will be used only for background patterns

thumbnailFormatPng = ThumbnailFormat;

//@description The thumbnail is in TGS format. It will be used only for sticker sets

thumbnailFormatTgs = ThumbnailFormat;

//@description The thumbnail is in WEBM format. It will be used only for sticker sets

thumbnailFormatWebm = ThumbnailFormat;

//@description The thumbnail is in WEBP format. It will be used only for some stickers and sticker sets

thumbnailFormatWebp = ThumbnailFormat;

//@description Represents a thumbnail

//@format Thumbnail format

//@width Thumbnail width

//@height Thumbnail height

//@file The thumbnail

thumbnail format:ThumbnailFormat width:int32 height:int32 file:file = Thumbnail;

//@class MaskPoint @description Part of the face, relative to which a mask is placed

//@description The mask is placed relatively to the forehead

maskPointForehead = MaskPoint;

//@description The mask is placed relatively to the eyes

maskPointEyes = MaskPoint;

//@description The mask is placed relatively to the mouth

maskPointMouth = MaskPoint;

//@description The mask is placed relatively to the chin

maskPointChin = MaskPoint;

//@description Position on a photo where a mask is placed

//@point Part of the face, relative to which the mask is placed

//@x_shift Shift by X-axis measured in widths of the mask scaled to the face size, from left to right. (For example, -1.0 will place the mask just to the left of the default mask position)

//@y_shift Shift by Y-axis measured in heights of the mask scaled to the face size, from top to bottom. (For example, 1.0 will place the mask just below the default mask position)

//@scale Mask scaling coefficient. (For example, 2.0 means a doubled size)

maskPosition point:MaskPoint x_shift:double y_shift:double scale:double = MaskPosition;

//@class StickerFormat @description Describes format of a sticker

//@description The sticker is an image in WEBP format

stickerFormatWebp = StickerFormat;

//@description The sticker is an animation in TGS format

stickerFormatTgs = StickerFormat;

//@description The sticker is a video in WEBM format

stickerFormatWebm = StickerFormat;

//@class StickerType @description Describes type of sticker

//@description The sticker is a regular sticker

stickerTypeRegular = StickerType;

//@description The sticker is a mask in WEBP format to be placed on photos or videos

stickerTypeMask = StickerType;

//@description The sticker is a custom emoji to be used inside message text and caption

stickerTypeCustomEmoji = StickerType;

//@class StickerFullType @description Contains full information about sticker type

//@description The sticker is a regular sticker @premium_animation Premium animation of the sticker; may be null. If present, only Telegram Premium users can use the sticker

stickerFullTypeRegular premium_animation:file = StickerFullType;

//@description The sticker is a mask in WEBP format to be placed on photos or videos @mask_position Position where the mask is placed; may be null

stickerFullTypeMask mask_position:maskPosition = StickerFullType;

//@description The sticker is a custom emoji to be used inside message text and caption. Currently, only Telegram Premium users can use custom emoji

//@custom_emoji_id Identifier of the custom emoji

//@needs_repainting True, if the sticker must be repainted to a text color in messages, the color of the Telegram Premium badge in emoji status, white color on chat photos, or another appropriate color in other places

stickerFullTypeCustomEmoji custom_emoji_id:int64 needs_repainting:Bool = StickerFullType;

//@description Represents a closed vector path. The path begins at the end point of the last command @commands List of vector path commands

closedVectorPath commands:vector<VectorPathCommand> = ClosedVectorPath;

//@description Describes one answer option of a poll

//@text Option text; 1-100 characters. Only custom emoji entities are allowed

//@voter_count Number of voters for this option, available only for closed or voted polls

//@vote_percentage The percentage of votes for this option; 0-100

//@is_chosen True, if the option was chosen by the user

//@is_being_chosen True, if the option is being chosen by a pending setPollAnswer request

pollOption text:formattedText voter_count:int32 vote_percentage:int32 is_chosen:Bool is_being_chosen:Bool = PollOption;

//@class PollType @description Describes the type of poll

//@description A regular poll @allow_multiple_answers True, if multiple answer options can be chosen simultaneously

pollTypeRegular allow_multiple_answers:Bool = PollType;

//@description A poll in quiz mode, which has exactly one correct answer option and can be answered only once

//@correct_option_id 0-based identifier of the correct answer option; -1 for a yet unanswered poll

//@explanation Text that is shown when the user chooses an incorrect answer or taps on the lamp icon; 0-200 characters with at most 2 line feeds; empty for a yet unanswered poll

pollTypeQuiz correct_option_id:int32 explanation:formattedText = PollType;

//@description Describes an animation file. The animation must be encoded in GIF or MPEG4 format

//@duration Duration of the animation, in seconds; as defined by the sender

//@width Width of the animation

//@height Height of the animation

//@file_name Original name of the file; as defined by the sender

//@mime_type MIME type of the file, usually "image/gif" or "video/mp4"

//@has_stickers True, if stickers were added to the animation. The list of corresponding sticker set can be received using getAttachedStickerSets

//@minithumbnail Animation minithumbnail; may be null

//@thumbnail Animation thumbnail in JPEG or MPEG4 format; may be null

//@animation File containing the animation

animation duration:int32 width:int32 height:int32 file_name:string mime_type:string has_stickers:Bool minithumbnail:minithumbnail thumbnail:thumbnail animation:file = Animation;

//@description Describes an audio file. Audio is usually in MP3 or M4A format

//@duration Duration of the audio, in seconds; as defined by the sender

//@title Title of the audio; as defined by the sender

//@performer Performer of the audio; as defined by the sender

//@file_name Original name of the file; as defined by the sender

//@mime_type The MIME type of the file; as defined by the sender

//@album_cover_minithumbnail The minithumbnail of the album cover; may be null

//@album_cover_thumbnail The thumbnail of the album cover in JPEG format; as defined by the sender. The full size thumbnail is expected to be extracted from the downloaded audio file; may be null

//@external_album_covers Album cover variants to use if the downloaded audio file contains no album cover. Provided thumbnail dimensions are approximate

//@audio File containing the audio

audio duration:int32 title:string performer:string file_name:string mime_type:string album_cover_minithumbnail:minithumbnail album_cover_thumbnail:thumbnail external_album_covers:vector<thumbnail> audio:file = Audio;

//@description Describes a document of any type

//@file_name Original name of the file; as defined by the sender

//@mime_type MIME type of the file; as defined by the sender

//@minithumbnail Document minithumbnail; may be null

//@thumbnail Document thumbnail in JPEG or PNG format (PNG will be used only for background patterns); as defined by the sender; may be null

//@document File containing the document

document file_name:string mime_type:string minithumbnail:minithumbnail thumbnail:thumbnail document:file = Document;

//@description Describes a photo

//@has_stickers True, if stickers were added to the photo. The list of corresponding sticker sets can be received using getAttachedStickerSets

//@minithumbnail Photo minithumbnail; may be null

//@sizes Available variants of the photo, in different sizes

photo has_stickers:Bool minithumbnail:minithumbnail sizes:vector<photoSize> = Photo;

//@description Describes a sticker

//@id Unique sticker identifier within the set; 0 if none

//@set_id Identifier of the sticker set to which the sticker belongs; 0 if none

//@width Sticker width; as defined by the sender

//@height Sticker height; as defined by the sender

//@emoji Emoji corresponding to the sticker

//@format Sticker format

//@full_type Sticker's full type

//@outline Sticker's outline represented as a list of closed vector paths; may be empty. The coordinate system origin is in the upper-left corner

//@thumbnail Sticker thumbnail in WEBP or JPEG format; may be null

//@sticker File containing the sticker

sticker id:int64 set_id:int64 width:int32 height:int32 emoji:string format:StickerFormat full_type:StickerFullType outline:vector<closedVectorPath> thumbnail:thumbnail sticker:file = Sticker;

//@description Describes a video file

//@duration Duration of the video, in seconds; as defined by the sender

//@width Video width; as defined by the sender

//@height Video height; as defined by the sender

//@file_name Original name of the file; as defined by the sender

//@mime_type MIME type of the file; as defined by the sender

//@has_stickers True, if stickers were added to the video. The list of corresponding sticker sets can be received using getAttachedStickerSets

//@supports_streaming True, if the video is expected to be streamed

//@minithumbnail Video minithumbnail; may be null

//@thumbnail Video thumbnail in JPEG or MPEG4 format; as defined by the sender; may be null

//@video File containing the video

video duration:int32 width:int32 height:int32 file_name:string mime_type:string has_stickers:Bool supports_streaming:Bool minithumbnail:minithumbnail thumbnail:thumbnail video:file = Video;

//@description Describes a video note. The video must be equal in width and height, cropped to a circle, and stored in MPEG4 format

//@duration Duration of the video, in seconds; as defined by the sender

//@waveform A waveform representation of the video note's audio in 5-bit format; may be empty if unknown

//@length Video width and height; as defined by the sender

//@minithumbnail Video minithumbnail; may be null

//@thumbnail Video thumbnail in JPEG format; as defined by the sender; may be null

//@speech_recognition_result Result of speech recognition in the video note; may be null

//@video File containing the video

videoNote duration:int32 waveform:bytes length:int32 minithumbnail:minithumbnail thumbnail:thumbnail speech_recognition_result:SpeechRecognitionResult video:file = VideoNote;

//@description Describes a voice note

//@duration Duration of the voice note, in seconds; as defined by the sender

//@waveform A waveform representation of the voice note in 5-bit format

//@mime_type MIME type of the file; as defined by the sender. Usually, one of "audio/ogg" for Opus in an OGG container, "audio/mpeg" for an MP3 audio, or "audio/mp4" for an M4A audio

//@speech_recognition_result Result of speech recognition in the voice note; may be null

//@voice File containing the voice note

voiceNote duration:int32 waveform:bytes mime_type:string speech_recognition_result:SpeechRecognitionResult voice:file = VoiceNote;

//@description Describes an animated or custom representation of an emoji

//@sticker Sticker for the emoji; may be null if yet unknown for a custom emoji. If the sticker is a custom emoji, then it can have arbitrary format

//@sticker_width Expected width of the sticker, which can be used if the sticker is null

//@sticker_height Expected height of the sticker, which can be used if the sticker is null

//@fitzpatrick_type Emoji modifier fitzpatrick type; 0-6; 0 if none

//@sound File containing the sound to be played when the sticker is clicked; may be null. The sound is encoded with the Opus codec, and stored inside an OGG container

animatedEmoji sticker:sticker sticker_width:int32 sticker_height:int32 fitzpatrick_type:int32 sound:file = AnimatedEmoji;

//@description Describes a user contact

//@phone_number Phone number of the user

//@first_name First name of the user; 1-255 characters in length

//@last_name Last name of the user

//@vcard Additional data about the user in a form of vCard; 0-2048 bytes in length

//@user_id Identifier of the user, if known; 0 otherwise

contact phone_number:string first_name:string last_name:string vcard:string user_id:int53 = Contact;

//@description Describes a location on planet Earth

//@latitude Latitude of the location in degrees; as defined by the sender

//@longitude Longitude of the location, in degrees; as defined by the sender

//@horizontal_accuracy The estimated horizontal accuracy of the location, in meters; as defined by the sender. 0 if unknown

location latitude:double longitude:double horizontal_accuracy:double = Location;

//@description Describes a venue

//@location Venue location; as defined by the sender

//@title Venue name; as defined by the sender

//@address Venue address; as defined by the sender

//@provider Provider of the venue database; as defined by the sender. Currently, only "foursquare" and "gplaces" (Google Places) need to be supported

//@id Identifier of the venue in the provider database; as defined by the sender

//@type Type of the venue in the provider database; as defined by the sender

venue location:location title:string address:string provider:string id:string type:string = Venue;

//@description Describes a game. Use getInternalLink with internalLinkTypeGame to share the game

//@id Unique game identifier

//@short_name Game short name

//@title Game title

//@text Game text, usually containing scoreboards for a game

//@param_description Game description

//@photo Game photo

//@animation Game animation; may be null

game id:int64 short_name:string title:string text:formattedText description:string photo:photo animation:animation = Game;

//@description Describes a Web App. Use getInternalLink with internalLinkTypeWebApp to share the Web App

//@short_name Web App short name

//@title Web App title

//@param_description Web App description

//@photo Web App photo

//@animation Web App animation; may be null

webApp short_name:string title:string description:string photo:photo animation:animation = WebApp;

//@description Describes a poll

//@id Unique poll identifier

//@question Poll question; 1-300 characters. Only custom emoji entities are allowed

//@options List of poll answer options

//@total_voter_count Total number of voters, participating in the poll

//@recent_voter_ids Identifiers of recent voters, if the poll is non-anonymous

//@is_anonymous True, if the poll is anonymous

//@type Type of the poll

//@open_period Amount of time the poll will be active after creation, in seconds

//@close_date Point in time (Unix timestamp) when the poll will automatically be closed

//@is_closed True, if the poll is closed

poll id:int64 question:formattedText options:vector<pollOption> total_voter_count:int32 recent_voter_ids:vector<MessageSender> is_anonymous:Bool type:PollType open_period:int32 close_date:int32 is_closed:Bool = Poll;

//@description Describes an alternative reencoded quality of a video file

//@width Video width

//@height Video height

//@codec Codec used for video file encoding, for example, "h264", "h265", or "av1"

//@hls_file HLS file describing the video

//@video File containing the video

alternativeVideo width:int32 height:int32 codec:string hls_file:file video:file = AlternativeVideo;

//@description Describes a chat background

//@id Unique background identifier

//@is_default True, if this is one of default backgrounds

//@is_dark True, if the background is dark and is recommended to be used with dark theme

//@name Unique background name

//@document Document with the background; may be null. Null only for filled and chat theme backgrounds

//@type Type of the background

background id:int64 is_default:Bool is_dark:Bool name:string document:document type:BackgroundType = Background;

//@description Contains a list of backgrounds @backgrounds A list of backgrounds

backgrounds backgrounds:vector<background> = Backgrounds;

//@description Describes a background set for a specific chat @background The background @dark_theme_dimming Dimming of the background in dark themes, as a percentage; 0-100. Applied only to Wallpaper and Fill types of background

chatBackground background:background dark_theme_dimming:int32 = ChatBackground;

//@description Describes a user profile photo

//@id Photo identifier; 0 for an empty photo. Can be used to find a photo in a list of user profile photos

//@small A small (160x160) user profile photo. The file can be downloaded only before the photo is changed

//@big A big (640x640) user profile photo. The file can be downloaded only before the photo is changed

//@minithumbnail User profile photo minithumbnail; may be null

//@has_animation True, if the photo has animated variant

//@is_personal True, if the photo is visible only for the current user

profilePhoto id:int64 small:file big:file minithumbnail:minithumbnail has_animation:Bool is_personal:Bool = ProfilePhoto;

//@description Contains basic information about the photo of a chat

//@small A small (160x160) chat photo variant in JPEG format. The file can be downloaded only before the photo is changed

//@big A big (640x640) chat photo variant in JPEG format. The file can be downloaded only before the photo is changed

//@minithumbnail Chat photo minithumbnail; may be null

//@has_animation True, if the photo has animated variant

//@is_personal True, if the photo is visible only for the current user

chatPhotoInfo small:file big:file minithumbnail:minithumbnail has_animation:Bool is_personal:Bool = ChatPhotoInfo;

//@class UserType @description Represents the type of user. The following types are possible: regular users, deleted users and bots

//@description A regular user

userTypeRegular = UserType;

//@description A deleted user or deleted bot. No information on the user besides the user identifier is available. It is not possible to perform any active actions on this type of user

userTypeDeleted = UserType;

//@description A bot (see https://core.telegram.org/bots)

//@can_be_edited True, if the bot is owned by the current user and can be edited using the methods toggleBotUsernameIsActive, reorderBotActiveUsernames, setBotProfilePhoto, setBotName, setBotInfoDescription, and setBotInfoShortDescription

//@can_join_groups True, if the bot can be invited to basic group and supergroup chats

//@can_read_all_group_messages True, if the bot can read all messages in basic group or supergroup chats and not just those addressed to the bot. In private and channel chats a bot can always read all messages

//@has_main_web_app True, if the bot has the main Web App

//@is_inline True, if the bot supports inline queries

//@inline_query_placeholder Placeholder for inline queries (displayed on the application input field)

//@need_location True, if the location of the user is expected to be sent with every inline query to this bot

//@can_connect_to_business True, if the bot supports connection to Telegram Business accounts

//@can_be_added_to_attachment_menu True, if the bot can be added to attachment or side menu

//@active_user_count The number of recently active users of the bot

userTypeBot can_be_edited:Bool can_join_groups:Bool can_read_all_group_messages:Bool has_main_web_app:Bool is_inline:Bool inline_query_placeholder:string need_location:Bool can_connect_to_business:Bool can_be_added_to_attachment_menu:Bool active_user_count:int32 = UserType;

//@description No information on the user besides the user identifier is available, yet this user has not been deleted. This object is extremely rare and must be handled like a deleted user. It is not possible to perform any actions on users of this type

userTypeUnknown = UserType;

//@description Represents a command supported by a bot @command Text of the bot command @param_description Description of the bot command

botCommand command:string description:string = BotCommand;

//@description Contains a list of bot commands @bot_user_id Bot's user identifier @commands List of bot commands

botCommands bot_user_id:int53 commands:vector<botCommand> = BotCommands;

//@description Describes a button to be shown instead of bot commands menu button

//@text Text of the button

//@url URL of a Web App to open when the button is pressed. If the link is of the type internalLinkTypeWebApp, then it must be processed accordingly. Otherwise, the link must be passed to openWebApp

botMenuButton text:string url:string = BotMenuButton;

//@description Represents a location to which a chat is connected @location The location @address Location address; 1-64 characters, as defined by the chat owner

chatLocation location:location address:string = ChatLocation;

//@description Represents a birthdate of a user @day Day of the month; 1-31 @month Month of the year; 1-12 @year Birth year; 0 if unknown

birthdate day:int32 month:int32 year:int32 = Birthdate;

//@description Describes a user that had or will have a birthday soon @user_id User identifier @birthdate Birthdate of the user

closeBirthdayUser user_id:int53 birthdate:birthdate = CloseBirthdayUser;

//@class BusinessAwayMessageSchedule @description Describes conditions for sending of away messages by a Telegram Business account

//@description Send away messages always

businessAwayMessageScheduleAlways = BusinessAwayMessageSchedule;

//@description Send away messages outside of the business opening hours

businessAwayMessageScheduleOutsideOfOpeningHours = BusinessAwayMessageSchedule;

//@description Send away messages only in the specified time span

//@start_date Point in time (Unix timestamp) when the away messages will start to be sent

//@end_date Point in time (Unix timestamp) when the away messages will stop to be sent

businessAwayMessageScheduleCustom start_date:int32 end_date:int32 = BusinessAwayMessageSchedule;

//@description Represents a location of a business @location The location; may be null if not specified @address Location address; 1-96 characters

businessLocation location:location address:string = BusinessLocation;

//@description Describes private chats chosen for automatic interaction with a business

//@chat_ids Identifiers of selected private chats

//@excluded_chat_ids Identifiers of private chats that are always excluded; for businessConnectedBot only

//@select_existing_chats True, if all existing private chats are selected

//@select_new_chats True, if all new private chats are selected

//@select_contacts True, if all private chats with contacts are selected

//@select_non_contacts True, if all private chats with non-contacts are selected

//@exclude_selected If true, then all private chats except the selected are chosen. Otherwise, only the selected chats are chosen

businessRecipients chat_ids:vector<int53> excluded_chat_ids:vector<int53> select_existing_chats:Bool select_new_chats:Bool select_contacts:Bool select_non_contacts:Bool exclude_selected:Bool = BusinessRecipients;

//@description Describes settings for messages that are automatically sent by a Telegram Business account when it is away

//@shortcut_id Unique quick reply shortcut identifier for the away messages

//@recipients Chosen recipients of the away messages

//@schedule Settings used to check whether the current user is away

//@offline_only True, if the messages must not be sent if the account was online in the last 10 minutes

businessAwayMessageSettings shortcut_id:int32 recipients:businessRecipients schedule:BusinessAwayMessageSchedule offline_only:Bool = BusinessAwayMessageSettings;

//@description Describes settings for greeting messages that are automatically sent by a Telegram Business account as response to incoming messages in an inactive private chat

//@shortcut_id Unique quick reply shortcut identifier for the greeting messages

//@recipients Chosen recipients of the greeting messages

//@inactivity_days The number of days after which a chat will be considered as inactive; currently, must be on of 7, 14, 21, or 28

businessGreetingMessageSettings shortcut_id:int32 recipients:businessRecipients inactivity_days:int32 = BusinessGreetingMessageSettings;

//@description Describes a bot connected to a business account

//@bot_user_id User identifier of the bot

//@recipients Private chats that will be accessible to the bot

//@can_reply True, if the bot can send messages to the private chats; false otherwise

businessConnectedBot bot_user_id:int53 recipients:businessRecipients can_reply:Bool = BusinessConnectedBot;

//@description Describes settings for a business account start page

//@title Title text of the start page

//@message Message text of the start page

//@sticker Greeting sticker of the start page; may be null if none

businessStartPage title:string message:string sticker:sticker = BusinessStartPage;

//@description Describes settings for a business account start page to set

//@title Title text of the start page; 0-getOption("business_start_page_title_length_max") characters

//@message Message text of the start page; 0-getOption("business_start_page_message_length_max") characters

//@sticker Greeting sticker of the start page; pass null if none. The sticker must belong to a sticker set and must not be a custom emoji

inputBusinessStartPage title:string message:string sticker:InputFile = InputBusinessStartPage;

//@description Describes an interval of time when the business is open

//@start_minute The minute's sequence number in a week, starting on Monday, marking the start of the time interval during which the business is open; 0-7*24*60

//@end_minute The minute's sequence number in a week, starting on Monday, marking the end of the time interval during which the business is open; 1-8*24*60

businessOpeningHoursInterval start_minute:int32 end_minute:int32 = BusinessOpeningHoursInterval;

//@description Describes opening hours of a business @time_zone_id Unique time zone identifier @opening_hours Intervals of the time when the business is open

businessOpeningHours time_zone_id:string opening_hours:vector<businessOpeningHoursInterval> = BusinessOpeningHours;

//@description Contains information about a Telegram Business account

//@location Location of the business; may be null if none

//@opening_hours Opening hours of the business; may be null if none. The hours are guaranteed to be valid and has already been split by week days

//@local_opening_hours Opening hours of the business in the local time; may be null if none. The hours are guaranteed to be valid and has already been split by week days.

//-Local time zone identifier will be empty. An updateUserFullInfo update is not triggered when value of this field changes

//@next_open_in Time left before the business will open the next time, in seconds; 0 if unknown. An updateUserFullInfo update is not triggered when value of this field changes

//@next_close_in Time left before the business will close the next time, in seconds; 0 if unknown. An updateUserFullInfo update is not triggered when value of this field changes

//@greeting_message_settings The greeting message; may be null if none or the Business account is not of the current user

//@away_message_settings The away message; may be null if none or the Business account is not of the current user

//@start_page Information about start page of the account; may be null if none

businessInfo location:businessLocation opening_hours:businessOpeningHours local_opening_hours:businessOpeningHours next_open_in:int32 next_close_in:int32 greeting_message_settings:businessGreetingMessageSettings away_message_settings:businessAwayMessageSettings start_page:businessStartPage = BusinessInfo;

//@description Contains information about a business chat link

//@link The HTTPS link

//@text Message draft text that will be added to the input field

//@title Link title

//@view_count Number of times the link was used

businessChatLink link:string text:formattedText title:string view_count:int32 = BusinessChatLink;

//@description Contains a list of business chat links created by the user @links List of links

businessChatLinks links:vector<businessChatLink> = BusinessChatLinks;

//@description Describes a business chat link to create or edit

//@text Message draft text that will be added to the input field

//@title Link title

inputBusinessChatLink text:formattedText title:string = InputBusinessChatLink;

//@description Contains information about a business chat link

//@chat_id Identifier of the private chat that created the link

//@text Message draft text that must be added to the input field

businessChatLinkInfo chat_id:int53 text:formattedText = BusinessChatLinkInfo;

//@class ChatPhotoStickerType @description Describes type of sticker, which was used to create a chat photo

//@description Information about the sticker, which was used to create the chat photo

//@sticker_set_id Sticker set identifier

//@sticker_id Identifier of the sticker in the set

chatPhotoStickerTypeRegularOrMask sticker_set_id:int64 sticker_id:int64 = ChatPhotoStickerType;

//@description Information about the custom emoji, which was used to create the chat photo

//@custom_emoji_id Identifier of the custom emoji

chatPhotoStickerTypeCustomEmoji custom_emoji_id:int64 = ChatPhotoStickerType;

//@description Information about the sticker, which was used to create the chat photo. The sticker is shown at the center of the photo and occupies at most 67% of it

//@type Type of the sticker

//@background_fill The fill to be used as background for the sticker; rotation angle in backgroundFillGradient isn't supported

chatPhotoSticker type:ChatPhotoStickerType background_fill:BackgroundFill = ChatPhotoSticker;

//@description Animated variant of a chat photo in MPEG4 format

//@length Animation width and height

//@file Information about the animation file

//@main_frame_timestamp Timestamp of the frame, used as a static chat photo

animatedChatPhoto length:int32 file:file main_frame_timestamp:double = AnimatedChatPhoto;

//@description Describes a chat or user profile photo

//@id Unique photo identifier

//@added_date Point in time (Unix timestamp) when the photo has been added

//@minithumbnail Photo minithumbnail; may be null

//@sizes Available variants of the photo in JPEG format, in different size

//@animation A big (up to 1280x1280) animated variant of the photo in MPEG4 format; may be null

//@small_animation A small (160x160) animated variant of the photo in MPEG4 format; may be null even the big animation is available

//@sticker Sticker-based version of the chat photo; may be null

chatPhoto id:int64 added_date:int32 minithumbnail:minithumbnail sizes:vector<photoSize> animation:animatedChatPhoto small_animation:animatedChatPhoto sticker:chatPhotoSticker = ChatPhoto;

//@description Contains a list of chat or user profile photos @total_count Total number of photos @photos List of photos

chatPhotos total_count:int32 photos:vector<chatPhoto> = ChatPhotos;

//@class InputChatPhoto @description Describes a photo to be set as a user profile or chat photo

//@description A previously used profile photo of the current user @chat_photo_id Identifier of the current user's profile photo to reuse

inputChatPhotoPrevious chat_photo_id:int64 = InputChatPhoto;

//@description A static photo in JPEG format @photo Photo to be set as profile photo. Only inputFileLocal and inputFileGenerated are allowed

inputChatPhotoStatic photo:InputFile = InputChatPhoto;

//@description An animation in MPEG4 format; must be square, at most 10 seconds long, have width between 160 and 1280 and be at most 2MB in size

//@animation Animation to be set as profile photo. Only inputFileLocal and inputFileGenerated are allowed

//@main_frame_timestamp Timestamp of the frame, which will be used as static chat photo

inputChatPhotoAnimation animation:InputFile main_frame_timestamp:double = InputChatPhoto;

//@description A sticker on a custom background @sticker Information about the sticker

inputChatPhotoSticker sticker:chatPhotoSticker = InputChatPhoto;

//@description Describes actions that a user is allowed to take in a chat

//@can_send_basic_messages True, if the user can send text messages, contacts, giveaways, giveaway winners, invoices, locations, and venues

//@can_send_audios True, if the user can send music files

//@can_send_documents True, if the user can send documents

//@can_send_photos True, if the user can send photos

//@can_send_videos True, if the user can send videos

//@can_send_video_notes True, if the user can send video notes

//@can_send_voice_notes True, if the user can send voice notes

//@can_send_polls True, if the user can send polls

//@can_send_other_messages True, if the user can send animations, games, stickers, and dice and use inline bots

//@can_add_link_previews True, if the user may add a link preview to their messages

//@can_change_info True, if the user can change the chat title, photo, and other settings

//@can_invite_users True, if the user can invite new users to the chat

//@can_pin_messages True, if the user can pin messages

//@can_create_topics True, if the user can create topics

chatPermissions can_send_basic_messages:Bool can_send_audios:Bool can_send_documents:Bool can_send_photos:Bool can_send_videos:Bool can_send_video_notes:Bool can_send_voice_notes:Bool can_send_polls:Bool can_send_other_messages:Bool can_add_link_previews:Bool can_change_info:Bool can_invite_users:Bool can_pin_messages:Bool can_create_topics:Bool = ChatPermissions;

//@description Describes rights of the administrator

//@can_manage_chat True, if the administrator can access the chat event log, get boost list, see hidden supergroup and channel members, report supergroup spam messages and ignore slow mode. Implied by any other privilege; applicable to supergroups and channels only

//@can_change_info True, if the administrator can change the chat title, photo, and other settings

//@can_post_messages True, if the administrator can create channel posts or view channel statistics; applicable to channels only

//@can_edit_messages True, if the administrator can edit messages of other users and pin messages; applicable to channels only

//@can_delete_messages True, if the administrator can delete messages of other users

//@can_invite_users True, if the administrator can invite new users to the chat

//@can_restrict_members True, if the administrator can restrict, ban, or unban chat members or view supergroup statistics; always true for channels

//@can_pin_messages True, if the administrator can pin messages; applicable to basic groups and supergroups only

//@can_manage_topics True, if the administrator can create, rename, close, reopen, hide, and unhide forum topics; applicable to forum supergroups only

//@can_promote_members True, if the administrator can add new administrators with a subset of their own privileges or demote administrators that were directly or indirectly promoted by them

//@can_manage_video_chats True, if the administrator can manage video chats

//@can_post_stories True, if the administrator can create new chat stories, or edit and delete posted stories; applicable to supergroups and channels only

//@can_edit_stories True, if the administrator can edit stories posted by other users, post stories to the chat page, pin chat stories, and access story archive; applicable to supergroups and channels only

//@can_delete_stories True, if the administrator can delete stories posted by other users; applicable to supergroups and channels only

//@is_anonymous True, if the administrator isn't shown in the chat member list and sends messages anonymously; applicable to supergroups only

chatAdministratorRights can_manage_chat:Bool can_change_info:Bool can_post_messages:Bool can_edit_messages:Bool can_delete_messages:Bool can_invite_users:Bool can_restrict_members:Bool can_pin_messages:Bool can_manage_topics:Bool can_promote_members:Bool can_manage_video_chats:Bool can_post_stories:Bool can_edit_stories:Bool can_delete_stories:Bool is_anonymous:Bool = ChatAdministratorRights;

//@description Describes subscription plan paid in Telegram Stars

//@period The number of seconds between consecutive Telegram Star debiting

//@star_count The amount of Telegram Stars that must be paid for each period

starSubscriptionPricing period:int32 star_count:int53 = StarSubscriptionPricing;

//@description Contains information about subscription to a channel chat paid in Telegram Stars

//@id Unique identifier of the subscription

//@chat_id Identifier of the channel chat that is subscribed

//@expiration_date Point in time (Unix timestamp) when the subscription will expire or expired

//@can_reuse True, if the subscription is active and the user can use the method reuseStarSubscription to join the subscribed chat again

//@is_canceled True, if the subscription was canceled

//@is_expiring True, if the subscription expires soon and there are no enough Telegram Stars on the user's balance to extend it

//@invite_link The invite link that can be used to renew the subscription if it has been expired; may be empty, if the link isn't available anymore

//@pricing The subscription plan

starSubscription id:string chat_id:int53 expiration_date:int32 can_reuse:Bool is_canceled:Bool is_expiring:Bool invite_link:string pricing:starSubscriptionPricing = StarSubscription;

//@description Represents a list of Telegram Star subscriptions

//@star_count The amount of owned Telegram Stars

//@subscriptions List of subscriptions for Telegram Stars

//@required_star_count The number of Telegram Stars required to buy to extend subscriptions expiring soon

//@next_offset The offset for the next request. If empty, then there are no more results

starSubscriptions star_count:int53 subscriptions:vector<starSubscription> required_star_count:int53 next_offset:string = StarSubscriptions;

//@description Contains information about a product that can be paid with invoice

//@title Product title

//@param_description Product description

//@photo Product photo; may be null

productInfo title:string description:formattedText photo:photo = ProductInfo;

//@description Describes an option for buying Telegram Premium to a user

//@currency ISO 4217 currency code for Telegram Premium subscription payment

//@amount The amount to pay, in the smallest units of the currency

//@discount_percentage The discount associated with this option, as a percentage

//@month_count Number of months the Telegram Premium subscription will be active. Use getPremiumInfoSticker to get the sticker to be used as representation of the Telegram Premium subscription

//@store_product_id Identifier of the store product associated with the option

//@payment_link An internal link to be opened for buying Telegram Premium to the user if store payment isn't possible; may be null if direct payment isn't available

premiumPaymentOption currency:string amount:int53 discount_percentage:int32 month_count:int32 store_product_id:string payment_link:InternalLinkType = PremiumPaymentOption;

//@description Describes an option for buying or upgrading Telegram Premium for self

//@payment_option Information about the payment option

//@is_current True, if this is the currently used Telegram Premium subscription option

//@is_upgrade True, if the payment option can be used to upgrade the existing Telegram Premium subscription

//@last_transaction_id Identifier of the last in-store transaction for the currently used option

premiumStatePaymentOption payment_option:premiumPaymentOption is_current:Bool is_upgrade:Bool last_transaction_id:string = PremiumStatePaymentOption;

//@description Describes an option for creating Telegram Premium gift codes or Telegram Premium giveaway. Use telegramPaymentPurposePremiumGiftCodes or telegramPaymentPurposePremiumGiveaway for out-of-store payments

//@currency ISO 4217 currency code for Telegram Premium gift code payment

//@amount The amount to pay, in the smallest units of the currency

//@discount_percentage The discount associated with this option, as a percentage

//@winner_count Number of users which will be able to activate the gift codes

//@month_count Number of months the Telegram Premium subscription will be active

//@store_product_id Identifier of the store product associated with the option; may be empty if none

//@store_product_quantity Number of times the store product must be paid

//@sticker A sticker to be shown along with the gift code; may be null if unknown

premiumGiftCodePaymentOption currency:string amount:int53 discount_percentage:int32 winner_count:int32 month_count:int32 store_product_id:string store_product_quantity:int32 sticker:sticker = PremiumGiftCodePaymentOption;

//@description Contains a list of options for creating Telegram Premium gift codes or Telegram Premium giveaway @options The list of options

premiumGiftCodePaymentOptions options:vector<premiumGiftCodePaymentOption> = PremiumGiftCodePaymentOptions;

//@description Contains information about a Telegram Premium gift code

//@creator_id Identifier of a chat or a user that created the gift code; may be null if unknown. If null and the code is from messagePremiumGiftCode message, then creator_id from the message can be used

//@creation_date Point in time (Unix timestamp) when the code was created

//@is_from_giveaway True, if the gift code was created for a giveaway

//@giveaway_message_id Identifier of the corresponding giveaway message in the creator_id chat; can be 0 or an identifier of a deleted message

//@month_count Number of months the Telegram Premium subscription will be active after code activation

//@user_id Identifier of a user for which the code was created; 0 if none

//@use_date Point in time (Unix timestamp) when the code was activated; 0 if none

premiumGiftCodeInfo creator_id:MessageSender creation_date:int32 is_from_giveaway:Bool giveaway_message_id:int53 month_count:int32 user_id:int53 use_date:int32 = PremiumGiftCodeInfo;

//@description Describes an option for buying Telegram Stars. Use telegramPaymentPurposeStars for out-of-store payments

//@currency ISO 4217 currency code for the payment

//@amount The amount to pay, in the smallest units of the currency

//@star_count Number of Telegram Stars that will be purchased

//@store_product_id Identifier of the store product associated with the option; may be empty if none

//@is_additional True, if the option must be shown only in the full list of payment options

starPaymentOption currency:string amount:int53 star_count:int53 store_product_id:string is_additional:Bool = StarPaymentOption;

//@description Contains a list of options for buying Telegram Stars @options The list of options

starPaymentOptions options:vector<starPaymentOption> = StarPaymentOptions;

//@description Describes an option for the number of winners of a Telegram Star giveaway

//@winner_count The number of users that will be chosen as winners

//@won_star_count The number of Telegram Stars that will be won by the winners of the giveaway

//@is_default True, if the option must be chosen by default

starGiveawayWinnerOption winner_count:int32 won_star_count:int53 is_default:Bool = StarGiveawayWinnerOption;

//@description Describes an option for creating Telegram Star giveaway. Use telegramPaymentPurposeStarGiveaway for out-of-store payments

//@currency ISO 4217 currency code for the payment

//@amount The amount to pay, in the smallest units of the currency

//@star_count Number of Telegram Stars that will be distributed among winners

//@store_product_id Identifier of the store product associated with the option; may be empty if none

//@yearly_boost_count Number of times the chat will be boosted for one year if the option is chosen

//@winner_options Allowed options for the number of giveaway winners

//@is_default True, if the option must be chosen by default

//@is_additional True, if the option must be shown only in the full list of payment options

starGiveawayPaymentOption currency:string amount:int53 star_count:int53 store_product_id:string yearly_boost_count:int32 winner_options:vector<starGiveawayWinnerOption> is_default:Bool is_additional:Bool = StarGiveawayPaymentOption;

//@description Contains a list of options for creating Telegram Star giveaway @options The list of options

starGiveawayPaymentOptions options:vector<starGiveawayPaymentOption> = StarGiveawayPaymentOptions;

//@description Describes a gift that can be sent to another user

//@id Unique identifier of the gift

//@sticker The sticker representing the gift

//@star_count Number of Telegram Stars that must be paid for the gift

//@default_sell_star_count Number of Telegram Stars that can be claimed by the receiver instead of the gift by default. If the gift was paid with just bought Telegram Stars, then full value can be claimed

//@remaining_count Number of remaining times the gift can be purchased by all users; 0 if not limited or the gift was sold out

//@total_count Number of total times the gift can be purchased by all users; 0 if not limited

//@first_send_date Point in time (Unix timestamp) when the gift was send for the first time; for sold out gifts only

//@last_send_date Point in time (Unix timestamp) when the gift was send for the last time; for sold out gifts only

gift id:int64 sticker:sticker star_count:int53 default_sell_star_count:int53 remaining_count:int32 total_count:int32 first_send_date:int32 last_send_date:int32 = Gift;

//@description Contains a list of gifts that can be sent to another user @gifts The list of gifts

gifts gifts:vector<gift> = Gifts;

//@description Represents a gift received by a user

//@sender_user_id Identifier of the user that sent the gift; 0 if unknown

//@text Message added to the gift

//@is_private True, if the sender and gift text are shown only to the gift receiver; otherwise, everyone are able to see them

//@is_saved True, if the gift is displayed on the user's profile page; may be false only for the receiver of the gift

//@date Point in time (Unix timestamp) when the gift was sent

//@gift The gift

//@message_id Identifier of the message with the gift in the chat with the sender of the gift; can be 0 or an identifier of a deleted message; only for the gift receiver

//@sell_star_count Number of Telegram Stars that can be claimed by the receiver instead of the gift; only for the gift receiver

userGift sender_user_id:int53 text:formattedText is_private:Bool is_saved:Bool date:int32 gift:gift message_id:int53 sell_star_count:int53 = UserGift;

//@description Represents a list of gifts received by a user

//@total_count The total number of received gifts

//@gifts The list of gifts

//@next_offset The offset for the next request. If empty, then there are no more results

userGifts total_count:int32 gifts:vector<userGift> next_offset:string = UserGifts;

//@class StarTransactionDirection @description Describes direction of a transaction with Telegram Stars

//@description The transaction is incoming and increases the number of owned Telegram Stars

starTransactionDirectionIncoming = StarTransactionDirection;

//@description The transaction is outgoing and decreases the number of owned Telegram Stars

starTransactionDirectionOutgoing = StarTransactionDirection;

//@class BotTransactionPurpose @description Describes purpose of a transaction with a bot

//@description Paid media were bought @media The bought media if the transaction wasn't refunded @payload Bot-provided payload; for bots only

botTransactionPurposePaidMedia media:vector<PaidMedia> payload:string = BotTransactionPurpose;

//@description User bought a product from the bot

//@product_info Information about the bought product; may be null if not applicable

//@invoice_payload Invoice payload; for bots only

botTransactionPurposeInvoicePayment product_info:productInfo invoice_payload:bytes = BotTransactionPurpose;

//@class ChatTransactionPurpose @description Describes purpose of a transaction with a supergroup or a channel

//@description Paid media were bought

//@message_id Identifier of the corresponding message with paid media; can be 0 or an identifier of a deleted message

//@media The bought media if the transaction wasn't refunded

chatTransactionPurposePaidMedia message_id:int53 media:vector<PaidMedia> = ChatTransactionPurpose;

//@description User joined the channel and subscribed to regular payments in Telegram Stars

//@period The number of seconds between consecutive Telegram Star debiting

chatTransactionPurposeJoin period:int32 = ChatTransactionPurpose;

//@description User paid for a reaction

//@message_id Identifier of the reacted message; can be 0 or an identifier of a deleted message

chatTransactionPurposeReaction message_id:int53 = ChatTransactionPurpose;

//@description User received Telegram Stars from a giveaway @giveaway_message_id Identifier of the message with giveaway; can be 0 or an identifier of a deleted message

chatTransactionPurposeGiveaway giveaway_message_id:int53 = ChatTransactionPurpose;

//@class UserTransactionPurpose @description Describes purpose of a transaction with a user

//@description A user gifted Telegram Stars @sticker A sticker to be shown in the transaction information; may be null if unknown

userTransactionPurposeGiftedStars sticker:sticker = UserTransactionPurpose;

//@description The current user sold a gift received from another user @gift The gift

userTransactionPurposeGiftSell gift:gift = UserTransactionPurpose;

//@description The current user sent a gift to another user @gift The gift

userTransactionPurposeGiftSend gift:gift = UserTransactionPurpose;

//@class StarTransactionPartner @description Describes source or recipient of a transaction with Telegram Stars

//@description The transaction is a transaction with Telegram through a bot

starTransactionPartnerTelegram = StarTransactionPartner;

//@description The transaction is a transaction with App Store