if ($MAILDEL_CHOSEN | str downcase) == 'y' { $MAILDEL = true }

#!/usr/bin/env nu

# Implicit default method run:
def main [] {
    print "this is setup CLI"
}

# Subcommand (see usage example below),
# also implicitly has `--help` generated `email del --help` (can be improved)
# Args are between the [], a bool flag with long and short forms,
# and spread syntax to indicate the rest of the CLI args will be collected as a list variable
def "main email del" [--yes (-y), ...accounts] {
  # `let` is immutable (read-only) after assignment
  let force_skip = $yes

  # `mut` allow updating the variable after assignment
  mut should_delete = false
  if not $force_skip {
    print 'Do you want to delete the mailbox data as well (removing all mails)? [y/N]'
    # Read the next input from the user, lowercase it and compare to get true/false:
    # `--numchar 1` is like `read -n 1` stopping after the first char input from the user.
    # `--suppress-output` so regardless of char when input is not `y`, we later print `no`.
    $should_delete = (input --numchar 1 --suppress-output | str downcase) == 'y'

    # Alternative that provides an interactive prompt and converts selection to boolean:
    # https://github.com/nushell/nushell/issues/15124
    #$should_delete = try { (['no', 'yes'] | input list --index | into bool) } catch { false }

    # Formats the bool result as yes/no for optionally logging to stdout:
    print (if $should_delete { 'yes' } else { 'no' })
  }

  # Iterate through the array of 1 or more accounts:
  for account in $accounts {
    if $should_delete { delete_mailbox $account }
  }
}

# Pretend this has full functionality of `_remove_maildir()` :)
def delete_mailbox [account: string] {
  # This variable will split the email address at `@` into subfields `.local` + `.domain`:
  let mail_parts = ($account | split column --number 2 '@' local domain | first)

  let mailbox_path = $"/var/mail/($mail_parts.domain)/($mail_parts.local)"
  print $"Deleting Mailbox: '($mailbox_path)'"
}