AC_ARG_WITH([sanitizers],

[AS_HELP_STRING([--with-sanitizers],

[comma separated list of extra sanitizers to build with (default is none enabled)])],

[use_sanitizers=$withval])

if test x$use_sanitizers != x; then

# First check if the compiler accepts flags. If an incompatible pair like

# -fsanitize=address,thread is used here, this check will fail. This will also

# fail if a bad argument is passed, e.g. -fsanitize=undfeined

AX_CHECK_COMPILE_FLAG(

[[-fsanitize=$use_sanitizers]],

[[SANITIZER_CXXFLAGS=-fsanitize=$use_sanitizers]],

[AC_MSG_ERROR([compiler did not accept requested flags])])

# Some compilers (e.g. GCC) require additional libraries like libasan,

# libtsan, libubsan, etc. Make sure linking still works with the sanitize

# flag. This is a separate check so we can give a better error message when

# the sanitize flags are supported by the compiler but the actual sanitizer

# libs are missing.

AX_CHECK_LINK_FLAG(

[[-fsanitize=$use_sanitizers]],

[[SANITIZER_LDFLAGS=-fsanitize=$use_sanitizers]],

[AC_MSG_ERROR([linker did not accept requested flags, you are missing required libraries])])

fi

**Sanitizers**

Bitcoin can be compiled with various "sanitizers" enabled, which add

instrumentation for issues regarding things like memory safety, thread race

conditions, or undefined behavior. This is controlled with the

`--with-sanitizers` configure flag, which should be a comma separated list of

sanitizers to enable. The sanitizer list should correspond to supported

`-fsanitize=` options in your compiler. These sanitizers have runtime overhead,

so they are most useful when testing changes or producing debugging builds.

Some examples:

./configure --with-sanitizers=address,undefined

./configure --with-sanitizers=thread

If you are compiling with GCC you will typically need to install corresponding

"san" libraries to actually compile with these flags, e.g. libasan for the

address sanitizer, libtsan for the thread sanitizer, and libubsan for the

undefined sanitizer. If you are missing required libraries, the configure script

will fail with a linker error when testing the sanitizer flags.

The test suite should pass cleanly with the `thread` and `undefined` sanitizers,

but there are a number of known problems when using the `address` sanitizer. The

address sanitizer is known to fail in

[sha256_sse4::Transform](/src/crypto/sha256_sse4.cpp) which makes it unusable

unless you also use `--disable-asm` when running configure. We would like to fix

sanitizer issues, so please send pull requests if you can fix any errors found

by the address sanitizer (or any other sanitizer).

Not all sanitizer options can be enabled at the same time, e.g. trying to build

with `--with-sanitizers=address,thread` will fail in the configure script as

these sanitizers are mutually incompatible. Refer to your compiler manual to

learn more about these options and which sanitizers are supported by your

compiler.

Additional resources:

* [AddressSanitizer](https://clang.llvm.org/docs/AddressSanitizer.html)

* [LeakSanitizer](https://clang.llvm.org/docs/LeakSanitizer.html)

* [MemorySanitizer](https://clang.llvm.org/docs/MemorySanitizer.html)

* [ThreadSanitizer](https://clang.llvm.org/docs/ThreadSanitizer.html)

* [UndefinedBehaviorSanitizer](https://clang.llvm.org/docs/UndefinedBehaviorSanitizer.html)

* [GCC Instrumentation Options](https://gcc.gnu.org/onlinedocs/gcc/Instrumentation-Options.html)

* [Google Sanitizers Wiki](https://github.com/google/sanitizers/wiki)

* [Issue #12691: Enable -fsanitize flags in Travis](https://github.com/bitcoin/bitcoin/issues/12691)

AM_LDFLAGS = $(PTHREAD_CFLAGS) $(LIBTOOL_LDFLAGS) $(HARDENED_LDFLAGS) $(GPROF_LDFLAGS) $(SANITIZER_LDFLAGS)

AM_CXXFLAGS = $(HARDENED_CXXFLAGS) $(ERROR_CXXFLAGS) $(GPROF_CXXFLAGS) $(SANITIZER_CXXFLAGS)