Support tree artifact outputs in XCFramework rules (#2785)

luispadron · web-flow · commit 680c2275bfca · 2025-11-11T11:23:08.000-05:00
Manual cherry-pick of: 3276c83 One thing i noticed was `upstream` is generating different static xcframeworks than we are, i didnt want to change that in this PR and not entirely sure which is correct. Test from upstream: ``` expected_directories = { "ios_static_xcframework.xcframework": [ "Info.plist", "ios-arm64/ios_static_xcframework.a", "ios-arm64/Headers/ios_static_xcframework/ios_static_xcframework.h", "ios-arm64/Headers/ios_static_xcframework/module.modulemap", "ios-arm64/Headers/ios_static_xcframework/shared.h", "ios-arm64_x86_64-simulator/ios_static_xcframework.a", "ios-arm64_x86_64-simulator/Headers/ios_static_xcframework/ios_static_xcframework.h", "ios-arm64_x86_64-simulator/Headers/ios_static_xcframework/module.modulemap", "ios-arm64_x86_64-simulator/Headers/ios_static_xcframework/shared.h", ], }, ``` Compared to what is created in `master` today: ``` expected_directories = { "ios_static_xcframework.xcframework": [ "Info.plist", "ios-arm64/ios_static_xcframework.framework/ios_static_xcframework", "ios-arm64/ios_static_xcframework.framework/Headers/ios_static_xcframework.h", "ios-arm64/ios_static_xcframework.framework/Headers/shared.h", "ios-arm64/ios_static_xcframework.framework/Modules/module.modulemap", "ios-arm64_x86_64-simulator/ios_static_xcframework.framework/ios_static_xcframework", "ios-arm64_x86_64-simulator/ios_static_xcframework.framework/Headers/ios_static_xcframework.h", "ios-arm64_x86_64-simulator/ios_static_xcframework.framework/Headers/shared.h", "ios-arm64_x86_64-simulator/ios_static_xcframework.framework/Modules/module.modulemap", ], }, ```
diff --git a/apple/internal/outputs.bzl b/apple/internal/outputs.bzl
@@ -37,6 +37,7 @@ def _archive(
         bundle_extension,
         bundle_name,
         label_name,
+        output_discriminator = "",
         platform_prerequisites,
         predeclared_outputs,
         rule_descriptor):
@@ -53,6 +54,11 @@ def _archive(
             return actions.declare_directory(
                 paths.join(root_path, archive_relative_path, bundle_name_with_extension),
             )
+        if output_discriminator:
+            return actions.declare_directory(paths.join(
+                output_discriminator,
+                bundle_name_with_extension,
+            ))
 
         return actions.declare_directory(bundle_name_with_extension)
     return predeclared_outputs.archive
diff --git a/apple/internal/partials/apple_bundle_info.bzl b/apple/internal/partials/apple_bundle_info.bzl
@@ -49,6 +49,7 @@ def _apple_bundle_info_partial_impl(
         bundle_name = bundle_name,
         bundle_extension = bundle_extension,
         label_name = label_name,
+        output_discriminator = output_discriminator,
         platform_prerequisites = platform_prerequisites,
         predeclared_outputs = predeclared_outputs,
         rule_descriptor = rule_descriptor,
diff --git a/apple/internal/partials/codesigning_dossier.bzl b/apple/internal/partials/codesigning_dossier.bzl
@@ -315,6 +315,7 @@ def _codesigning_dossier_partial_impl(
         bundle_extension = bundle_extension,
         bundle_name = bundle_name,
         label_name = label_name,
+        output_discriminator = output_discriminator,
         platform_prerequisites = platform_prerequisites,
         predeclared_outputs = predeclared_outputs,
         rule_descriptor = rule_descriptor,
diff --git a/apple/internal/processor.bzl b/apple/internal/processor.bzl
@@ -753,6 +753,7 @@ def _process(
             bundle_extension = bundle_extension,
             bundle_name = bundle_name,
             label_name = rule_label.name,
+            output_discriminator = output_discriminator,
             platform_prerequisites = platform_prerequisites,
             predeclared_outputs = predeclared_outputs,
             rule_descriptor = rule_descriptor,
diff --git a/apple/internal/xcframework_rules.bzl b/apple/internal/xcframework_rules.bzl
@@ -422,20 +422,27 @@ def _create_xcframework_root_infoplist(
 def _create_xcframework_bundle(
         *,
         actions,
+        apple_fragment,
+        apple_mac_toolchain_info,
+        apple_xplat_toolchain_info,
         bundle_name,
-        bundletool,
         framework_archive_files,
         framework_archive_merge_files,
         framework_archive_merge_zips = [],
         label_name,
         output_archive,
-        root_info_plist):
+        root_info_plist,
+        tree_artifact_enabled,
+        xcode_config):
     """Generates the bundle archive for an XCFramework.
 
      Args:
         actions: The actions providerx from `ctx.actions`.
+        apple_fragment: An Apple fragment (ctx.fragments.apple).
+        apple_mac_toolchain_info: The `AppleMacToolsToolchainInfo` provider from the mac toolchain.
+        apple_xplat_toolchain_info: The `AppleXPlatToolsToolchainInfo` provider from the xplat
+            toolchain.
         bundle_name: The name of the XCFramework bundle.
-        bundletool: A files to run for the bundle tool.
         framework_archive_files: A list of depsets referencing files to be used as inputs to the
             bundling action. This should include every archive referenced as a "src" of
             framework_archive_merge_zips.
@@ -451,6 +458,8 @@ def _create_xcframework_bundle(
         label_name: Name of the target being built.
         output_archive: The file representing the final bundled archive.
         root_info_plist: A `File` representing a fully formed root Info.plist for this XCFramework.
+        tree_artifact_enabled: A boolean indicating whether tree artifact outputs are enabled.
+        xcode_config: The `apple_common.XcodeVersionConfig` provider from the context.
     """
     bundletool_control_file = intermediates.file(
         actions = actions,
@@ -471,17 +480,43 @@ def _create_xcframework_bundle(
         content = json.encode(bundletool_control),
     )
 
-    actions.run(
-        arguments = [bundletool_control_file.path],
-        executable = bundletool,
-        inputs = depset(
-            direct = [bundletool_control_file, root_info_plist],
-            transitive = framework_archive_files,
-        ),
-        mnemonic = "CreateXCFrameworkBundle",
-        outputs = [output_archive],
-        progress_message = "Bundling %s" % label_name,
-    )
+    if tree_artifact_enabled:
+        bundletool = apple_mac_toolchain_info.bundletool_experimental
+        apple_support.run(
+            actions = actions,
+            apple_fragment = apple_fragment,
+            arguments = [bundletool_control_file.path],
+            executable = bundletool,
+            execution_requirements = {
+                # Added so that the output of this action is not cached remotely, in case multiple
+                # developers sign the same artifact with different identities.
+                "no-remote": "1",
+                # Unsure, but may be needed for keychain access, especially for files that live in
+                # $HOME.
+                "no-sandbox": "1",
+            },
+            inputs = depset(
+                direct = [bundletool_control_file, root_info_plist],
+                transitive = framework_archive_files,
+            ),
+            mnemonic = "CreateXCFrameworkBundle",
+            outputs = [output_archive],
+            progress_message = "Bundling %s" % label_name,
+            xcode_config = xcode_config,
+        )
+    else:
+        bundletool = apple_xplat_toolchain_info.bundletool
+        actions.run(
+            arguments = [bundletool_control_file.path],
+            executable = bundletool,
+            inputs = depset(
+                direct = [bundletool_control_file, root_info_plist],
+                transitive = framework_archive_files,
+            ),
+            mnemonic = "CreateXCFrameworkBundle",
+            outputs = [output_archive],
+            progress_message = "Bundling %s" % label_name,
+        )
 
 def _apple_xcframework_impl(ctx):
     """Implementation of apple_xcframework."""
@@ -492,12 +527,18 @@ def _apple_xcframework_impl(ctx):
     cc_toolchain_forwarder = ctx.split_attr._cc_toolchain_forwarder
     executable_name = getattr(ctx.attr, "executable_name", bundle_name)
     deps = ctx.split_attr.deps
+    xcode_config = ctx.attr._xcode_config[apple_common.XcodeVersionConfig]
 
+    tree_artifact_enabled = False
+    outputs_archive = ctx.outputs.archive
     if (apple_xplat_toolchain_info.build_settings.use_tree_artifacts_outputs or
         is_experimental_tree_artifact_enabled(config_vars = ctx.var)):
-        fail("The apple_xcframework rule does not yet support the experimental tree artifact. " +
-             "Please ensure that the `apple.experimental.tree_artifact_outputs` variable is not " +
-             "set to 1 on the command line or in your active build configuration.")
+        actions.write(
+            output = ctx.outputs.archive,
+            content = "This is a dummy file because tree artifacts are enabled",
+        )
+        tree_artifact_enabled = True
+        outputs_archive = actions.declare_directory(bundle_name + ".xcframework")
 
     # Add the disable_legacy_signing feature to the list of features
     # TODO(b/72148898): Remove this when dossier based signing becomes the default.
@@ -553,7 +594,7 @@ def _apple_xcframework_impl(ctx):
         deps = deps,
         label_name = label.name,
         link_result = link_result,
-        xcode_config = ctx.attr._xcode_config[apple_common.XcodeVersionConfig],
+        xcode_config = xcode_config,
     )
 
     available_libraries = []
@@ -741,10 +782,25 @@ def _apple_xcframework_impl(ctx):
         for provider in processor_result.providers:
             # Save the framework archive.
             if getattr(provider, "archive", None):
-                # Repackage every archive found for bundle_merge_zips in the final bundler action.
-                framework_archive_merge_zips.append(
-                    struct(src = provider.archive.path, dest = library_identifier),
-                )
+                # Repackage every archive found for bundle_merge_files or bundle_merge_zips in the
+                # final bundler action, depending on whether tree artifacts are enabled.
+                if tree_artifact_enabled:
+                    framework_archive_merge_files.append(
+                        struct(
+                            src = provider.archive.path,
+                            dest = paths.join(
+                                library_identifier,
+                                bundle_name + nested_bundle_extension,
+                            ),
+                        ),
+                    )
+                else:
+                    framework_archive_merge_zips.append(
+                        struct(
+                            src = provider.archive.path,
+                            dest = library_identifier,
+                        ),
+                    )
 
                 # Save a reference to those archives as file-friendly inputs to the bundler action.
                 framework_archive_files.append(depset([provider.archive]))
@@ -775,25 +831,29 @@ def _apple_xcframework_impl(ctx):
         available_libraries = available_libraries,
         plisttool = apple_mac_toolchain_info.plisttool,
         rule_label = label,
-        xcode_config = ctx.attr._xcode_config[apple_common.XcodeVersionConfig],
+        xcode_config = xcode_config,
     )
 
     _create_xcframework_bundle(
         actions = actions,
+        apple_fragment = ctx.fragments.apple,
+        apple_mac_toolchain_info = apple_mac_toolchain_info,
+        apple_xplat_toolchain_info = apple_xplat_toolchain_info,
         bundle_name = bundle_name,
-        bundletool = apple_xplat_toolchain_info.bundletool,
         framework_archive_files = framework_archive_files,
         framework_archive_merge_files = framework_archive_merge_files,
         framework_archive_merge_zips = framework_archive_merge_zips,
         label_name = label.name,
-        output_archive = ctx.outputs.archive,
+        output_archive = outputs_archive,
         root_info_plist = root_info_plist,
+        tree_artifact_enabled = tree_artifact_enabled,
+        xcode_config = xcode_config,
     )
 
     processor_output = [
         # Limiting the contents of AppleBundleInfo to what is necessary for testing and validation.
         new_applebundleinfo(
-            archive = ctx.outputs.archive,
+            archive = outputs_archive,
             bundle_extension = ".xcframework",
             bundle_id = nested_bundle_id,
             bundle_name = bundle_name,
@@ -803,7 +863,7 @@ def _apple_xcframework_impl(ctx):
         ),
         new_applexcframeworkbundleinfo(),
         DefaultInfo(
-            files = depset([ctx.outputs.archive], transitive = framework_output_files),
+            files = depset([outputs_archive], transitive = framework_output_files),
         ),
         OutputGroupInfo(
             **outputs.merge_output_groups(
@@ -970,9 +1030,19 @@ def _apple_static_xcframework_impl(ctx):
         requested_features = ctx.features,
         unsupported_features = ctx.disabled_features,
     )
-    outputs_archive = ctx.outputs.archive
     xcode_config = ctx.attr._xcode_config[apple_common.XcodeVersionConfig]
 
+    tree_artifact_enabled = False
+    outputs_archive = ctx.outputs.archive
+    if (apple_xplat_toolchain_info.build_settings.use_tree_artifacts_outputs or
+        is_experimental_tree_artifact_enabled(config_vars = ctx.var)):
+        actions.write(
+            output = ctx.outputs.archive,
+            content = "This is a dummy file because tree artifacts are enabled",
+        )
+        tree_artifact_enabled = True
+        outputs_archive = actions.declare_directory(bundle_name + ".xcframework")
+
     archive_result = linking_support.register_static_library_archive_action(
         ctx = ctx,
         cc_toolchains = cc_toolchain_forwarder,
@@ -1145,13 +1215,17 @@ def _apple_static_xcframework_impl(ctx):
 
     _create_xcframework_bundle(
         actions = actions,
+        apple_fragment = apple_fragment,
+        apple_mac_toolchain_info = apple_mac_toolchain_info,
+        apple_xplat_toolchain_info = apple_xplat_toolchain_info,
         bundle_name = bundle_name,
-        bundletool = apple_xplat_toolchain_info.bundletool,
         framework_archive_files = framework_archive_files,
         framework_archive_merge_files = framework_archive_merge_files,
         label_name = label.name,
         output_archive = outputs_archive,
         root_info_plist = root_info_plist,
+        tree_artifact_enabled = tree_artifact_enabled,
+        xcode_config = xcode_config,
     )
 
     return [
diff --git a/test/starlark_tests/apple_static_xcframework_tests.bzl b/test/starlark_tests/apple_static_xcframework_tests.bzl
@@ -14,6 +14,10 @@
 
 """xcframework Starlark tests."""
 
+load(
+    "//apple/build_settings:build_settings.bzl",
+    "build_settings_labels",
+)
 load(
     "//test/starlark_tests/rules:analysis_failure_message_test.bzl",
     "analysis_failure_message_test",
@@ -22,6 +26,10 @@ load(
     "//test/starlark_tests/rules:common_verification_tests.bzl",
     "archive_contents_test",
 )
+load(
+    "//test/starlark_tests/rules:directory_test.bzl",
+    "directory_test",
+)
 load(
     ":common.bzl",
     "common",
@@ -283,6 +291,54 @@ def apple_static_xcframework_test_suite(name):
         tags = [name],
     )
 
+    directory_test(
+        name = "{}_ios_static_library_xcframework_tree_artifact_test".format(name),
+        build_settings = {
+            build_settings_labels.use_tree_artifacts_outputs: "True",
+        },
+        target_under_test = "//test/starlark_tests/targets_under_test/apple:ios_static_xcframework",
+        expected_directories = {
+            "ios_static_xcframework.xcframework": [
+                "Info.plist",
+                "ios-arm64/ios_static_xcframework.framework/ios_static_xcframework",
+                "ios-arm64/ios_static_xcframework.framework/Headers/ios_static_xcframework.h",
+                "ios-arm64/ios_static_xcframework.framework/Headers/shared.h",
+                "ios-arm64/ios_static_xcframework.framework/Modules/module.modulemap",
+                "ios-arm64_x86_64-simulator/ios_static_xcframework.framework/ios_static_xcframework",
+                "ios-arm64_x86_64-simulator/ios_static_xcframework.framework/Headers/ios_static_xcframework.h",
+                "ios-arm64_x86_64-simulator/ios_static_xcframework.framework/Headers/shared.h",
+                "ios-arm64_x86_64-simulator/ios_static_xcframework.framework/Modules/module.modulemap",
+            ],
+        },
+        tags = [name],
+    )
+
+    directory_test(
+        name = "{}_ios_static_framework_xcframework_tree_artifact_test".format(name),
+        build_settings = {
+            build_settings_labels.use_tree_artifacts_outputs: "True",
+        },
+        target_under_test = "//test/starlark_tests/targets_under_test/apple:ios_static_framework_xcframework_with_deps_resource_bundle",
+        expected_directories = {
+            "ios_static_framework_xcframework_with_deps_resource_bundle.xcframework": [
+                "Info.plist",
+                "ios-arm64/ios_static_framework_xcframework_with_deps_resource_bundle.framework/ios_static_framework_xcframework_with_deps_resource_bundle",
+                "ios-arm64/ios_static_framework_xcframework_with_deps_resource_bundle.framework/Headers/ios_static_framework_xcframework_with_deps_resource_bundle.h",
+                "ios-arm64/ios_static_framework_xcframework_with_deps_resource_bundle.framework/Headers/shared.h",
+                "ios-arm64/ios_static_framework_xcframework_with_deps_resource_bundle.framework/Modules/module.modulemap",
+                "ios-arm64/ios_static_framework_xcframework_with_deps_resource_bundle.framework/resource_bundle.bundle/custom_apple_resource_info.out",
+                "ios-arm64/ios_static_framework_xcframework_with_deps_resource_bundle.framework/resource_bundle.bundle/Info.plist",
+                "ios-x86_64-simulator/ios_static_framework_xcframework_with_deps_resource_bundle.framework/ios_static_framework_xcframework_with_deps_resource_bundle",
+                "ios-x86_64-simulator/ios_static_framework_xcframework_with_deps_resource_bundle.framework/Headers/ios_static_framework_xcframework_with_deps_resource_bundle.h",
+                "ios-x86_64-simulator/ios_static_framework_xcframework_with_deps_resource_bundle.framework/Headers/shared.h",
+                "ios-x86_64-simulator/ios_static_framework_xcframework_with_deps_resource_bundle.framework/Modules/module.modulemap",
+                "ios-x86_64-simulator/ios_static_framework_xcframework_with_deps_resource_bundle.framework/resource_bundle.bundle/custom_apple_resource_info.out",
+                "ios-x86_64-simulator/ios_static_framework_xcframework_with_deps_resource_bundle.framework/resource_bundle.bundle/Info.plist",
+            ],
+        },
+        tags = [name],
+    )
+
     native.test_suite(
         name = name,
         tags = [name],
diff --git a/test/starlark_tests/apple_xcframework_tests.bzl b/test/starlark_tests/apple_xcframework_tests.bzl
diff --git a/test/starlark_tests/rules/directory_test.bzl b/test/starlark_tests/rules/directory_test.bzl
diff --git a/test/starlark_tests/targets_under_test/apple/BUILD b/test/starlark_tests/targets_under_test/apple/BUILD
