Actividad: conocido el radio (r) de la figura que sigue a continuación calcular en función

del radio (r): el área del polígono regular interno DEKIJD (área coloreada como violeta
claro), el área de cada punta de la estrella (región amarilla), el área aguamarina y el
área marrón. Usando esos valores calcular y comprobar el área del círculo

Ayudas:
1) Ángulo de las puntas amarillas de la estrella: 36° (se deduce por construcción)
2) Formula de Herón: área=rc(s*(s-a)*(s-b)*(s-c)); con s=(a+b+c)/2;
3) Suma de los ángulos internos de:
a. Triángulo: 180°
b. Cuadrángulo: 360°
c. Pentágono: 540°
Actividad A: Escriba un programa en “PseInt” que haga lo siguiente:
Leer por pantalla el valor del radio r (r debe estar entre +3.5 y +17.5)
Calcular: el área del polígono regular interno DEKIJD (área coloreada como violeta
claro), el área de cada punta de la estrella (región amarilla), el área aguamarina y el
área del segmento (región verde). Usando esos valores calcular y comprobar el área del
círculo
Notas obligatorias
Obligatoriamente se debe utilizar la ley de los cosenos
Obligatoriamente para el cálculo de las áreas solo pueden utilizar la fórmula de Herón y
esta, debe ser invocada como función del programa
Se puede usar “Pitágoras” para deducir valores de los lados de un triángulo

SOLUCIÓN PARCIAL (falta verificar restricciones del enunciado):

Funcion vlr = Heron (a,b,c)

Definir vlr,s como real
s=(a+b+c)/2
vlr=rc(s*(s-a)*(s-b)*(s-c))
FinFuncion

Algoritmo Estrella_5_vertices_A
Definir r,ladoP,ladoMayorCA,alturaBF,alturaOF,ladoBE,ladoFE,ladoOE como real
Definir segmentos,areaCirculo,areaAmarilla,areapoliINT,areaAguamarina como real
r=10;
ladoP=rc(2.0*r^2*(1-cos(pi*72/180))) /// Ley de los cosenos
ladoMayorCA=rc(2.0*ladoP^2*(1-cos(pi*108/180))) /// Ley de los cosenos
alturaBF=rc(ladoP^2-(ladoMayorCA/2.0)^2); /// Teorema de Pitágoras
alturaOF=r-alturaBF
ladoBE=rc(ladoP^2/(2*(1-cos(pi*108/180)))) /// Ley de los cosenos
ladoFE=rc(ladoBE^2-alturaBF^2)
ladoOE=rc(alturaOF^2 + ladoFE^2) /// Teorema de Pitágoras
Escribir" .. radio:",r," .. lado del polígono:", ladoP," .. lado mayor:", ladoMayorCA
Escribir" .. altura BF:",alturaBF," .. altura OF:",alturaOF
Escribir" .. lado BE:",ladoBE," .. lado FE:",ladoFE," .. lado OE:",ladoOE
segmentos=5.0*((pi*r^2/5.0) - Heron(r,r,ladoP))
areaAmarilla=2.0*Heron(alturaBF,ladoBE,ladoFE)
areaAguamarina=Heron(ladoP,ladoBE,ladoBE)
areapoliINT=10*Heron(alturaOF,ladoOE,ladoFE)
areaCirculo = areapoliINT + 5*areaAguamarina + 5*areaAmarilla + segmentos
Escribir " .. área polinomio interno DEKIJD:",areapoliINT
Escribir " .. área Amarilla:",areaAmarilla
Escribir " .. área Aguamarina:",areaAguamarina
 Escribir " .. formula (pi)*(r^2):",(pi)*(r^2)
Escribir " .. comprobación (sumatoria de parciales):",areaCirculo
Escribir " .. diferencia:",areacirculo -(pi)*(r^2)
FinAlgoritmo

Actividad B: Escriba un programa directamente en “PYTHON” que haga lo mismo de la

actividad anterior, pero usando la ley de los senos

Nota: el programa debe ser lo más compacto posible (es lo que en clase hemos llamado
Python modificado)

Taller del 26 de octubre de 2021

/// Dados: el radio de un círculo, el triángulo

equilátero inscrito en el círculo,
/// cuyo primer vértice está a alfa (alfa grados),
determinar las coordenadas (x,y)
/// de sus vértices y las pendientes de los
segmentos de recta que forman
/// el triángulo equilátero
/// Restricciones: el valor del radio debe estar
entre 5 y 15;
/// y el valor de alfa entre 10° y 80°
///

Algoritmo Taller_de_oct26_2021
Definir x1,y1,r,alfa Como Real
 Definir x2,y2,m Como Real
Definir i como entero
Escribir sin saltar" .. dar r:";leer r
Escribir sin saltar" .. dar alfa:";leer alfa
i=0
Mientras i < 3 Hacer
i=i+1
x1 = r*cos(alfa*pi/180)
y1 = r*sen(alfa*pi/180)
x2 = r*cos((alfa + 120)*pi/180)
y2 = r*sen((alfa + 120)*pi/180)
Escribir" .. vertice",i," alfa:",alfa," x1:",x1," y1:",y1
Escribir" .. vertice",i+1," alfa:",alfa+120," x2:",x2," y2:",y2
Si (x2 - x1) = 0 Entonces
Escribir" .. pendiente tiende a infinito"
SiNo
m = (y2 - y1)/(x2 - x1)
Escribir" .. pendiente",i,":",m
FinSi
alfa = alfa + 120
FinMientras
FinAlgoritmo

Taller para desarrollar

Se conoce alfa en un rango [ 2° .. +89°]. Se conoce el radio (r) del círculo en un rango
[+4.05 .. 49.99]. El círculo está dentro del cuadrado cuyo lado es de 3*r (es decir ancho y
alto del cuadrado que está externo al círculo es tres veces el radio). Se pide calcular las
siguientes áreas: área 1 interna, área A interna y área 3 externa.
También se pide calcular las coordenadas de los vértices del triángulo equilátero inscrito
en el círculo.
NOTA OBLIGATORIA: debe utilizarse una función que calcule el área del triángulo usado
la fórmula de Herón

Áreas “Punta de la flecha”

Grafica “Punta de la Flecha”

Descripción de la figura “Punta de la flecha”
 Inscrita en círculo con centro en el origen (0, 0) de lado r
 Compuesta por un polígono de 4 lados cerrado e inscrita en el círculo (que llamaremos “Punta
de flecha”), cuyas coordenadas son las siguientes: punto 1 sobre el eje X con coordenada (r, 0);
punto 2 en el origen (0, 0); punto 3 (-r/2, r/2* √ 3 ) sobre el círculo a 120o (ciento veinte grados)
a partir del punto 1; punto 4 (-r/2, r/2* √ 3 ) sobre el círculo a 120o (ciento veinte grados) a
partir del punto 3.
 Los lados menores de la punta de flecha forman un ángulo exterior obtuso de 120 o (ciento
veinte grados) y presentan cada uno una longitud r
 Los lados mayores de la punta de flecha forman un ángulo interior agudo de 60 o (sesenta
2
grados) y presentan longitudes iguales de r¿ √ 3 => 2* r 2− r
√ 4
 Los lados adyacentes menor y mayor forman un ángulo interior agudo de 30 o (treinta grados)
Actividad1: calcular en función de r
 Area1: la perteneciente a la “Punta de flecha”
 Area2: la perteneciente dentro del círculo y excluyendo el área de la “Punta de flecha”
 Area3: la perteneciente fuera del círculo si el cuadrado regular tiene de lado 2.25 veces r

Actividad2: calcular en función de r cada una de las nueve áreas señaladas en la grafica

Talleres resueltos y talleres para desarrollar

Las actividades de talleres aquí expuestas se envían con el fin de
ir practicando pequeños programas de programación tanto
individualmente como en grupo, y como tal no deben enviarse al
profesor.
Las dudas, las aclaraciones, las inquietudes de este material,
que aparezcan; deben ser formuladas durante la hora de clase.
Ayudas:
Ecuación de un círculo concéntrico
X2 + Y2 = r2;
Ecuación de la recta y = mx + b
y 2− y 1 pendiente
m= b= y 1−m x1 intercepto en Y
x 2−x 1

−b intercepto en X
c=
m

Taller resuelto (en dos versiones)

/// Versión sin usar función Herón

Algoritmo Taller1A_en_grupo
///
/// Leer r (entre 5.0 y 10.0), r representa el valor del radio de un circulo
/// con centro en el origen
/// Leer x1,y1 (coordenada en el primer cuadrante y fuera de círculo) [Punto 1 -> P1]
/// Leer x2,y2 (coordenada en el segundo cuadrante y fuera del círculo) [Punto 2 -> P2]
/// P0 => origen X0=0.0, Y0=0.0
/// Calcular área triangulo que se forma con P0, P1 y P2
/// Versión sin usar función Herón
Definir r,X1,Y1,X2,Y2,a,b,c,p,Area Como Real;
///
r=0.0;
Mientras r<5.0 | r>10.0 Hacer
Escribir "Dar r entre 5.0 y 10.0 :"; Leer r;
FinMientras

X1=-1.0;Y1=-1.0;
Mientras X1^2+Y1^2<=r^2 | X1<=0.0 | Y1<=0.0 Hacer
 Escribir "Dar X1 dentro del primer cuadrante y fuera de círculo:";Leer X1;
Escribir "Dar Y1 dentro del primer cuadrante y fuera de círculo:";Leer Y1;
FinMientras

X2=1.0;Y2=-1.0;
Mientras X2^2+Y2^2<=r^2 | X2>=0.0 | Y2<=0.0 Hacer
Escribir "Dar X2 dentro del segundo cuadrante y fuera de círculo:";Leer X2;
Escribir "Dar Y2 dentro del segundo cuadrante y fuera de círculo:";Leer Y2;
FinMientras

a=rc(X1^2 + Y1^2); /// lado a que pasa por el origen

b=rc((X1-X2)^2 + (Y1-Y2)^2); /// segmento de recta entre P1 y P2
c=rc(X2^2 + Y2^2); /// lado c que pasa por el origen
p=(a+b+c)/2.0;
Area=rc(p*(p-a)*(p-b)*(p-c));
Escribir " a:",a," b:",b," c:",c;
Escribir"Área de triángulo P0 P1 P2: ",Area;
FinAlgoritmo

/// Versión usando una función denominada Herón

Funcion Area = Heron1 ( a,b,c )
Definir Area,p Como Real
p=(a+b+c)/2.0;
Area=rc(p*(p-a)*(p-b)*(p-c));
FinFuncion

Algoritmo Taller1A_en_grupo
/// Leer r (entre 5.0 y 10.0), r representa el valor del radio de un circulo
/// con centro en el origen
/// Leer x1,y1 (primer cuadrante y fuera de círculo) [Punto 1 -> P1]
/// Leer x2,y2 (segundo cuadrante y fuera del círculo) [Punto 2 -> P2]
/// P0 => origen X0=0.0, Y0=0.0
/// Calcular área triangulo que se forma con P0,P1 y P2
/// Versión usando una función denominada Herón
Definir r,X1,Y1,X2,Y2,a,b,c,p,Area Como Real;
r=0.0;
Mientras r<5.0 | r>10.0 Hacer
Escribir "Dar r:"; Leer r;
FinMientras
X1=-1.0;Y1=-1.0;
Mientras X1^2+Y1^2<=r^2 | X1<=0.0 | Y1<=0.0 Hacer
Escribir "Dar X1:";Leer X1;
Escribir "Dar Y1:";Leer Y1;
FinMientras
X2=1.0;Y2=-1.0;
Mientras X2^2+Y2^2<=r^2 | X2>=0.0 | Y2<=0.0 Hacer
Escribir "Dar X2:";Leer X2;
Escribir "Dar Y2:";Leer Y2;
FinMientras
 a=rc(X1^2 + Y1^2);
b=rc((X1-X2)^2 + (Y1-Y2)^2);
c=rc(X2^2 + Y2^2);
Area = Heron1 ( a,b,c )
Escribir " a:",a," b:",b," c:",c;
Escribir"Área de triángulo P0 P1 P2: ",Area;
FinAlgoritmo

Taller propuesto:
agregarle al taller anterior, que además de calcular el área del
triángulo, verifique si la recta que pasa por los puntos 1 y 2 (P1 y P2), es tangente, o
secante, o no secante-no tangente

Taller a desarrollar
/// Dado un pentágono regular (de lado l) inscrito en un círculo de radio (r) y según gráfica adjunta,
/// se pide calcular: a) área del polígono usando solo la fórmula Herón a través de una función
/// b: los valores de las pendientes de los segmentos de rectas que pasan por el origen O (O1, O2, O3, O4, O5)
/// Segmentos: del origen al vértice 1: tag(0°); del origen al vértice 2: tag(72°);
/// del origen al vértice 3: tag(144°); del origen al vértice 4: tag(216°); del origen al vértice 5: tag(288°)
/// Pentágono regular: la suma de sus ángulos internos 540° y sus 5 triángulos internos son isósceles
/// Ángulos de cada triángulo isósceles interno: 72°, 54°, 54°
/// Sea l, el lado externo del pentágono y r el radio del círculo concéntrico
/// leer (generar) r en el rango [+5.01 .. +10.00] con dos decimales
/// Usar gráfica donde el vértice 1 tiene como coordenada (+r,0) y es simétrico con respecto al eje x
Repita el taller anterior usando un decágono (polinomio regular de 10 lados)

Taller
/// Dado un pentágono regular (de lado l) inscrito en un círculo de radio (r), se pide calcular
/// en función de r el área de uno de los segmentos que se forman al inscribir el pentágono.
/// Pentágono regular: la suma de sus ángulos internos 540° y sus 5 triángulos internos son isósceles
/// Ángulos de cada triángulo isósceles interno: 72°, 54°, 54°
/// Sea l, el lado externo del pentágono y r el radio del circulo concéntrico
/// Generar r en el rango [+5.01 .. +10.00] con dos decimales

1 4

2 3

Taller
/// Dado un pentágono regular (de lado l) inscrito en un círculo de radio (r),
/// se pide calcular:
/// l en función de r,
/// el valor de las pendientes de las rectas que pasan por el origen, además también
/// las coordenadas de sus vértices de acuerdo a la gráfica mostrada.
/// Gráfica 1: El vértice 1 tiene como coordenada (+r,0) y es simétrico con respecto al eje x
/// Pentágono regular: la suma de sus ángulos internos 540° y sus 5 triángulos internos son isósceles
/// Ángulos de cada triángulo isósceles interno: 72°, 54°, 54°
/// Sea l, el lado externo del pentágono y r el radio del círculo concéntrico
/// leer (generar) r en el rango [+5.01 .. +10.00] con dos decimales
///
/// Recta del origen al vértice 1: tag(0°); del origen al vértice 2: tag(72°);
/// del origen al vértice 3: tag(144°); del origen al vértice 4: tag(216°); del origen al vértice 5: tag(288°)
///

Taller
/// Dado un pentágono regular (de lado l) inscrito en un círculo de radio (r), se pide calcular, de acuerdo a /// una de
las gráficas mostrada:
/// a) l en función de r;
/// b) calcular el valor de las pendientes de las rectas que pasan por el origen;
/// c) calcular las coordenadas de sus vértices;
/// d) calcular las pendientes de los lados externos que conforman el pentágono.
/// Gráfica 1: El vértice 1 tiene como coordenada (+r,0) y es simétrico con respecto al eje x
/// Gráfica 2: El vértice 2 tiene como coordenada (-r,0) y es simétrico con respecto al eje x
/// Gráfica 3: El vértice 3 tiene como coordenada (0,+r) y es simétrico con respecto al eje y
/// Gráfica 4: El vértice 4 tiene como coordenada (0,-r) y es simétrico con respecto al eje y
/// (Solución gráfica 1)
/// Pentágono regular: la suma de sus ángulos internos 540° y sus 5 triángulos internos son isósceles
/// Ángulos de cada triángulo isósceles interno: 72°, 54°, 54°
/// Sea l, el lado externo del pentágono y r el radio del círculo concéntrico
/// leer (generar) r en el rango [+5.01 .. +10.00] con dos decimales
/// Segmento del origen al vértice 1: tag(0°); segmento del origen al vértice 2: tag(72°);
/// segmento del origen al vértice 3: tag(144°);
/// segmento del origen al vértice 4: tag(216°);segmento del origen al vértice 5: tag(288°)
 1 4

2 3