From

From APL Wiki
Jump to navigation Jump to search
⊇ @

From (⊇ or @ and also called Select, or, humourously, Sane Indexing) is a primitive function that selects multiple major cells of its right argument using an array of indices given by its left. The primitive often offers additional functionality for a nested left argument, which varies from one language to another. It appears in SAX (as @), Extended Dyalog APL, dzaima/APL, and Kap (as ⊇), J (as {), and BQN (as ⊏).

Common usage

Select is commonly used to reorder the major cells of an array. For example, the following shuffles any array into random order:

Try it online!

      Shuffle←?⍨∘≢⊇⊢
      Shuffle 'abcdef'
fbdcea
Works in: dzaima/APL, Extended Dyalog APL

With Index, a compound function is needed, such as ⊂⍛⌷ (equivalently {(⊂⍺)⌷⍵}) or ⌷⍤0 99 in Dyalog APL (where 99 exceeds the system's maximum array rank).

In a case where the left argument is a permutation vector for the right argument, the functionality can rightfully be called Permute.

Select especially cleans up expressions for reordering. An ascending sort can be represented as ⍋⊇⊢ and "sort by" can be written as ⊇⍨∘⍋:

Try it online!

      'abcde' ⊇⍨∘⍋ 3 1 4 1 5
bdace
Works in: dzaima/APL, Extended Dyalog APL

Extensions

Scatter-point

In A Dictionary of APL, J, and SAX, a boxed left argument indicates that each element will be used independently to select a cell of the argument. The behavior on a single element is very similar to APL's Index function. { has a left rank of 0, so that results are mixed together and those with different shapes may be padded with fills. 

   ]a =. 4 4$(a.i.'A')}.a.
ABCD
EFGH
IJKL
MNOP
   0 3 2 { a
ABCD
MNOP
IJKL
   (0 0;3 3;2 3) { a
APL
Works in: J

The same functionality might be written with Index rather than Select by using the Rank operator (⍤) to map over the left argument.[1] The left argument must then be disclosed with {(⊃⍺)⌷⍵}, or more succinctly with Behind: 

      (1 1)(4 4)(3 4) (⊃⍛⌷⍤0 99) 4 4⍴⎕A
APL
Works in: Dyalog APL 20.0

History

From ({) was introduced in 1983 by Rationalized APL. This description introduced the characteristic feature of selection of multiple cells simultaneously, along with scatter-point indexing and the ability to exclude rather than include indices using a third level of boxing. It was expanded slightly in A Dictionary of APL to allow negative indices and was paired with monadic Catalogue, giving the same meaning for { now used in J. Roger Hui expressed his support for the new definition with a presentation at APL87,[2] and it was included in J from the earliest drafts in 1990—a limited version had even appeared in Arthur Whitney's one-page interpreter prototype.

SHARP APL followed A Dictionary of APL and used {, but this was later deprecated, programmers being told to use @ instead.[3]

The name Select and glyph ⊇ were introduced by Extended Dyalog APL, and subsequently adopted by dzaima/APL and Kap. In addition to including it in Extended and the later Dyalog APL Vision, Adám Brudzewsky described Select as a possible future Dyalog APL primitive in a presentation at Dyalog '22.[4]

BQN uses the name Select like Extended Dyalog APL but takes the direction of the glyph ⊏, as well as negative indexing, from J. For a nested left argument it uses a new extension: instead of viewing nesting as elaboration of each element of the left argument, it instead treats it as providing a list of left arguments to select from multiple axes of the right argument. This extension provides the functionality of APL's Index not by requiring the left argument as a whole to be enclosed but by requiring that each of its elements be an array.

See also

External links

Documentation

Publications

References

  1. ↑ Richard Park. Selecting from Arrays. Dyalog Webinar. 16 Apr 2020. (Presented in the form ((⊃⊣)⌷⊢)⍤0 99.)
  2. ↑ Roger Hui. Some Uses of { and } at APL87.
  3. ↑ Soliton Associates Limited. SHARP APL for UNIX Language Guide. Deprecated Primitives: Braces. 2000.
  4. ↑ Adám Brudzewsky. Filling the Core Language Gaps. Dyalog '22. 2022-10-13.
APL built-ins [edit]
Primitives (Timeline) Functions
Scalar
Monadic Conjugate ∙ Negate ∙ Signum ∙ Reciprocal ∙ Magnitude ∙ Exponential ∙ Natural Logarithm ∙ Floor ∙ Ceiling ∙ Factorial ∙ Not ∙ Pi Times ∙ Roll ∙ Type ∙ Imaginary ∙ Square Root ∙ Round
Dyadic Add ∙ Subtract ∙ Times ∙ Divide ∙ Residue ∙ Power ∙ Logarithm ∙ Minimum ∙ Maximum ∙ Binomial ∙ Comparison functions ∙ Boolean functions (And, Or, Nand, Nor) ∙ GCD ∙ LCM ∙ Circular ∙ Complex ∙ Root
Non-Scalar
Structural Shape ∙ Reshape ∙ Tally ∙ Depth ∙ Ravel ∙ Enlist ∙ Table ∙ Catenate ∙ Reverse ∙ Rotate ∙ Transpose ∙ Raze ∙ Mix ∙ Split ∙ Enclose ∙ Nest ∙ Cut (K) ∙ Pair ∙ Link ∙ Partitioned Enclose ∙ Partition
Selection First ∙ Pick ∙ Take ∙ Drop ∙ Unique ∙ Identity ∙ Stop ∙ Select ∙ Replicate ∙ Expand ∙ Set functions (Intersection ∙ Union ∙ Without) ∙ Bracket indexing ∙ Index ∙ Cartesian Product ∙ Sort
Selector Index generator ∙ Grade ∙ Index Of ∙ Interval Index ∙ Indices ∙ Deal ∙ Prefix and suffix vectors
Computational Match ∙ Not Match ∙ Membership ∙ Find ∙ Nub Sieve ∙ Encode ∙ Decode ∙ Matrix Inverse ∙ Matrix Divide ∙ Format ∙ Execute ∙ Materialise ∙ Range ∙ Count In
Operators Monadic Each ∙ Commute ∙ Constant ∙ Replicate ∙ Expand ∙ Reduce ∙ Windowed Reduce ∙ Scan ∙ Outer Product ∙ Key ∙ I-Beam ∙ Spawn ∙ Function axis ∙ Identity (Null, Ident)
Dyadic Bind ∙ Compositions (Compose, Reverse Compose, Beside, Withe, Atop, Over) ∙ Inner Product ∙ Determinant ∙ Power ∙ At ∙ Under ∙ Rank ∙ Depth ∙ Variant ∙ Stencil ∙ Cut ∙ Direct definition (operator) ∙ Identity (Lev, Dex)
Quad names Index origin ∙ Comparison tolerance ∙ Migration level ∙ Atomic vector
Retrieved from ‘https://aplwiki.com/index.php?title=From&oldid=12996’